games-strategy/naev: drop 0.12.1

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

2 files changed, 0 insertions, 117 deletions

diff --git a/games-strategy/naev/Manifest b/games-strategy/naev/Manifest
index cd15fa4679c8..6eea2e2b8274 100644
--- a/games-strategy/naev/Manifest
+++ b/games-strategy/naev/Manifest
@@ -1,2 +1 @@
-DIST naev-0.12.1-source.tar.xz 463479836 BLAKE2B 5643e66d88e078d242642d0010e2f001a29d248633f624364196749aa59ec32787bf23e1960784b9e81acf1c4309e7f0987f5afe2a2c12c257208822bc1cd174 SHA512 d6bbe25d930723fec1786f7160ef72091d1480714bdec2032a8d194aec281ca352eaab0a4b8af538b79068be972cf28fc81d681ff5659733cdc2044ad250a9df
 DIST naev-0.12.2-source.tar.xz 465301164 BLAKE2B 1a9af216a66677dbbdcf381eff9b638df47610e7a7e1ffe881234805594b40ebdf76adf413458b936a487a807f7238e1e45f2479fd8ae1fcca352cc584d48493 SHA512 898a1c4e820f1bad5b3abfdbf255d6a54363462e3eaf6bbcffd9f806398094100fa3776fb4bcbc8510b2a159cf73e49d9909213e671f979cbf7b4983e2f43b3e
diff --git a/games-strategy/naev/naev-0.12.1.ebuild b/games-strategy/naev/naev-0.12.1.ebuild
deleted file mode 100644
index eb81049661fb..000000000000
--- a/games-strategy/naev/naev-0.12.1.ebuild
+++ /dev/null
@@ -1,116 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-LUA_COMPAT=( luajit )
-PYTHON_COMPAT=( python3_{10..13} )
-inherit lua-single meson python-any-r1 virtualx xdg
-
-DESCRIPTION="2D space trading and combat game, in a similar vein to Escape Velocity"
-HOMEPAGE="https://naev.org/"
-SRC_URI="https://github.com/naev/naev/releases/download/v${PV}/${P}-source.tar.xz"
-
-LICENSE="
-	GPL-3+
-	Apache-2.0 BSD BSD-2 CC-BY-2.0 CC-BY-3.0 CC-BY-4.0 CC-BY-SA-3.0
-	CC-BY-SA-4.0 CC0-1.0 GPL-2+ MIT OFL-1.1 public-domain
-"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="doc"
-REQUIRED_USE="${LUA_REQUIRED_USE}"
-
-# tests are very basic, equivalent of just starting the game and checking if
-# can see the main menu -- but this breaks easily with software rendering and
-# some Xorg/mesa versions, simpler to do manually than try to keep this working
-RESTRICT="test"
-
-# dlopen: libglvnd
-RDEPEND="
-	${LUA_DEPS}
-	app-text/cmark:=
-	dev-games/physfs
-	dev-libs/libpcre2:=
-	dev-libs/libunibreak:=
-	dev-libs/libxml2
-	dev-libs/libyaml
-	dev-libs/nativefiledialog-extended
-	media-libs/freetype:2
-	media-libs/libglvnd
-	media-libs/libsdl2[joystick,opengl,video]
-	media-libs/libvorbis
-	media-libs/openal
-	media-libs/sdl2-image[png,webp]
-	net-libs/enet:1.3=
-	sci-libs/cholmod
-	sci-libs/cxsparse
-	sci-libs/openblas
-	sci-libs/suitesparse
-	sci-mathematics/glpk:=
-	virtual/libintl
-"
-DEPEND="
-	${RDEPEND}
-	test? (
-		dev-games/physfs[zip]
-		media-libs/libsdl2[X]
-	)
-"
-BDEPEND="
-	$(python_gen_any_dep 'dev-python/pyyaml[${PYTHON_USEDEP}]')
-	sys-devel/gettext
-	doc? (
-		app-text/doxygen
-		dev-lua/ldoc
-		media-gfx/graphviz
-	)
-	test? (
-		media-libs/mesa[llvm]
-		x11-base/xorg-server[-minimal]
-	)
-"
-
-python_check_deps() {
-	python_has_version "dev-python/pyyaml[${PYTHON_USEDEP}]"
-}
-
-pkg_setup() {
-	lua-single_pkg_setup
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# don't probe OpenGL for tests (avoids sandbox violations, bug #829369)
-	sed -i "/subdir('glcheck')/d" test/meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		# *can* do lua5-1 but upstream uses+test luajit most (bug #946881)
-		-Dluajit=enabled
-		$(meson_feature doc docs_c)
-		$(meson_feature doc docs_lua)
-	)
-
-	meson_src_configure
-}
-
-src_test() {
-	virtx meson_src_test
-}
-
-src_install() {
-	local DOCS=( CHANGELOG Readme.md )
-	meson_src_install
-
-	if use doc; then
-		dodir /usr/share/doc/${PF}/html
-		mv -- "${ED}"/usr/{doc/naev/{c,lua},share/doc/${PF}/html} || die
-		rm -r -- "${ED}"/usr/doc || die
-	fi
-
-	rm -r -- "${ED}"/usr/share/doc/naev || die
-}