gnome-base/gnome-desktop: bump to 3.34.5

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>

2 files changed, 78 insertions, 0 deletions

diff --git a/gnome-base/gnome-desktop/Manifest b/gnome-base/gnome-desktop/Manifest
index 701db86c4b43..7ba4bac82715 100644
--- a/gnome-base/gnome-desktop/Manifest
+++ b/gnome-base/gnome-desktop/Manifest
@@ -2,3 +2,4 @@ DIST gnome-desktop-2.32.1.tar.bz2 1633847 BLAKE2B 9c69504b0f904fe04bdaa2e2fd3c6f
 DIST gnome-desktop-3.32.2-patchset.tar.xz 7404 BLAKE2B ecc821d3338957d0a123d625607d727019d9500915a76ff6d10d3000e1fc1e51fc7c0382374752582aef641d005cd73d39148466b08c53dc1ce9872e73a21215 SHA512 0471f0a6d9213ea60e867bd4f381575f6a94fa0fde57cc1a360e2d4ef98c11f2f973d3d95347db8f24aacb2249ba84ffc4e35e05bb595d9d3b6debe561ed88da
 DIST gnome-desktop-3.32.2.tar.xz 709128 BLAKE2B f0335d1ad583f0b000c47826cd4b6eb24624862b22b00e9d42759ed1cfcf3dba6f091dd85504c9c8da8b9789bf78cf53d284942ba6e2d3c630db028b4a0a69c6 SHA512 7dfa5c3e4b77637cc40e6244eb8ce8cb314cf92d865b64e36c5dffa8a699e91c81bd359f0a89a725c064eafec965d2b9d119aa05f1de103cd836a4bff9119a99
 DIST gnome-desktop-3.34.4.tar.xz 715280 BLAKE2B 34ee3d4a36e7b8212d5285f766b030ae9369ec99be90dbf86a10f6b6727f221770c43db012c9e4634b8c95c7ffb97d435fb3555b1bc184ec4127538ba6ab261b SHA512 de3ac71725f4cc55b22af4f6f04516d9a5cbdd27876f302fc78c864c1461e444967de3dae3a6944124b33335c9e6f4f96b9de63053c582917509b90844acbe3f
+DIST gnome-desktop-3.34.5.tar.xz 718008 BLAKE2B a09daf4f575b26774beeef8e9edb4ed757ead7c0155aab4d7c132bf503d29096c40b06d52aa261594c6db367ac7a638c33de4445748ab3d94a095c23f8ddd705 SHA512 bc59b420d5698b15697404efcf452e830933efa23b6dba9011eade1c7521dbd4fb6f6e6e2be822d231611b2133e36f2ec42ed49ecabd175127366e0e7d59955c
diff --git a/gnome-base/gnome-desktop/gnome-desktop-3.34.5.ebuild b/gnome-base/gnome-desktop/gnome-desktop-3.34.5.ebuild
new file mode 100644
index 000000000000..5018ba92f323
--- /dev/null
+++ b/gnome-base/gnome-desktop/gnome-desktop-3.34.5.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson virtualx xdg
+
+DESCRIPTION="Library with common API for various GNOME modules"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
+
+LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
+SLOT="3/18" # subslot = libgnome-desktop-3 soname version
+IUSE="debug gtk-doc +introspection seccomp systemd udev"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+
+# cairo[X] needed for gnome-bg
+COMMON_DEPEND="
+	>=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
+	>=x11-libs/gtk+-3.3.6:3[X,introspection?]
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
+	x11-misc/xkeyboard-config
+	app-text/iso-codes
+	x11-libs/libX11
+	systemd? ( sys-apps/systemd:= )
+	udev? (
+		sys-apps/hwids
+		virtual/libudev:= )
+	seccomp? ( sys-libs/libseccomp )
+
+	x11-libs/cairo:=[X]
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+"
+DEPEND="${COMMON_DEPEND}
+	media-libs/fontconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	seccomp? ( sys-apps/bubblewrap )
+"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.1.2
+	dev-util/gdbus-codegen
+	gtk-doc? ( >=dev-util/gtk-doc-1.14 )
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	x11-base/xorg-proto
+	virtual/pkgconfig
+"
+# Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xorg-proto
+
+PATCHES=(
+	"${FILESDIR}"/3.32.2-optional-introspection.patch # add introspection meson option
+)
+
+src_prepare() {
+	# Don't build manual test programs that will never get run
+	sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dgnome_distributor=Gentoo
+		-Ddate_in_gnome_version=true
+		-Ddesktop_docs=true
+		$(meson_use debug debug_tools)
+		$(meson_use introspection)
+		$(meson_feature udev)
+		$(meson_feature systemd)
+		$(meson_use gtk-doc gtk_doc)
+		-Dinstalled_tests=false
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}