kde-frameworks/kfilemetadata: 5.112.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 68 insertions, 0 deletions

diff --git a/kde-frameworks/kfilemetadata/Manifest b/kde-frameworks/kfilemetadata/Manifest
index e7295cecb269..143433fed792 100644
--- a/kde-frameworks/kfilemetadata/Manifest
+++ b/kde-frameworks/kfilemetadata/Manifest
@@ -1,2 +1,3 @@
 DIST kfilemetadata-5.110.0.tar.xz 472980 BLAKE2B d309fc73104796b46c429ffafbc7f976142ab5d910a40cd5d165b983f4da794b6c449334f59172d8aeadffe5101fa6112ec619ab5c05f0543041dc5db9bd0222 SHA512 c97d3fd58c123c867227326a4576249e9afcabba0ded1420d1ccbcc51ce8ad537521f4f4c483f2830aefb00e19d45e7dd17abc429a97a622b2ac1f87b0dadb89
 DIST kfilemetadata-5.111.0.tar.xz 472952 BLAKE2B 12bc33b77fde194d57ed891be8795ef7a945581e8ec29333aecc79ad5bd48e9754ab5aa8fa93abb80f0d84f354d40147312f228e929ac671011f4ee21aa560aa SHA512 a7daadf131077331448f5df7f27b803d8140949c3feedab628b77f086ec52bbcc6520da032e46de97b4dd489bf663f39f611406b4014aba12cd9bfb9e08e7734
+DIST kfilemetadata-5.112.0.tar.xz 472928 BLAKE2B 9f0867b95abe33c37227d0955fd7044548baf1d1b07ccc74950d15d65e3c61cda0bca44198e0a2b12e3e7d2f763db436a7612ab5f5b5ecc9f6093e2415a51a1a SHA512 6d7e6a25c9360edc274baa5de578afe088e2d4c5ef53f81329b806defbcb7dd7084975b2367972a5a5d8915c07cc2cecc243e0ad750e443801f8c11d693aa787
diff --git a/kde-frameworks/kfilemetadata/kfilemetadata-5.112.0.ebuild b/kde-frameworks/kfilemetadata/kfilemetadata-5.112.0.ebuild
new file mode 100644
index 000000000000..336d6d7b24f5
--- /dev/null
+++ b/kde-frameworks/kfilemetadata/kfilemetadata-5.112.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+PVCUT=$(ver_cut 1-2)
+QTMIN=5.15.9
+inherit ecm frameworks.kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="epub exif ffmpeg mobi pdf taglib"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	=kde-frameworks/karchive-${PVCUT}*:5
+	=kde-frameworks/kcoreaddons-${PVCUT}*:5
+	=kde-frameworks/ki18n-${PVCUT}*:5
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mobi? ( kde-apps/kdegraphics-mobipocket:5 )
+	pdf? ( app-text/poppler[qt5] )
+	taglib? ( media-libs/taglib )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package mobi QMobipocket)
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	local myctestargs=( -E "(usermetadatawritertest)" )
+	ecm_src_test
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+	ecm_pkg_postinst
+}