kde-plasma/plasma-nm: 5.27.10 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index fd8e56b299d8..59f33db67d84 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1 +1,2 @@
+DIST plasma-nm-5.27.10.tar.xz 1155856 BLAKE2B e3633156c65991aa938ab60b429dd56f7f78a2ae49b7cbe2b21a8cfba6eefb2b490b69d540fbc4b62017b3ae28186eade08f93c059f2ec20ed4fa5946731095e SHA512 427e6b8ebcd471c0e09a483e43207e60367dae45f8d7727101559685fb9e8f5eaa1a6328a5fd6af4f0a39e7533495ed5402f2f34be9fa943099906d092b1739d
 DIST plasma-nm-5.27.9.tar.xz 1155540 BLAKE2B 923c50385ccfb3085d4bf2e429dde12e8afcc808de0d57d38161503b358b3ec090c458b53366a3e44baa604485860abf5a0cf97ce734fd72a2cb9b3ffd43b44a SHA512 e3e49da8d9093d5632e8200015046f47c576b15f74eb0d5b1ef26e1fbe75f532d02a5eb972e3fa4d4606036d9b3f9bd47f1e1822b39578fb830e91f9af286385
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.27.10.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.27.10.ebuild
new file mode 100644
index 000000000000..8420e63ec411
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.27.10.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.3.0:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-plasma/libplasma-${KFMIN}:5
+	net-misc/mobile-broadband-provider-info
+	net-misc/networkmanager[teamd=]
+	openconnect? (
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kquickcharts-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:*
+"
+BDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# TODO: try to get a build switch upstreamed
+	if ! use openconnect; then
+		sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}