kde-plasma/plasma-nm: 5.26.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 97 insertions, 0 deletions

diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index ea85a1bd995f..41f874798183 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-nm-5.25.5.tar.xz 950520 BLAKE2B 4dfd8bcff7bb6c176c5ead81f5e667df3411e89b15aff5f5e2615b0ad58084748b70585be81c82510c704bdd04269ef3348760bd69c6e5830bc1480837e158e8 SHA512 5aa1fc85e8f6b373419d188145d5501764f9aa8d246c2de7f7463483565216c6c0069d9a413993a861a083d55a504c01ea967888d9ac1ea2a7fae26b7bee06f4
 DIST plasma-nm-5.26.0.tar.xz 970672 BLAKE2B 6ca1f2a399848cecf24281922155d2a0adf2c1c948126403811dfbf19baea3a24238e4955ceb2238962fcb9e87fa2f1ab282de5c66178fe4f426991522164e6e SHA512 015a189816a058dd9af7b3abbf4fef6eb9f32bd6897f40749683c5609fd29082c2b646b3fb40d517ff38c001d1649a55f9537ea1487e4890d566c73abcd9e300
+DIST plasma-nm-5.26.1.tar.xz 970608 BLAKE2B 7f4cf45fb70a84002569d9e26f89c8f384bfff4ad38a25a297e53fa4f32b8884af15fc2beba2898f1a8238a92d287e8cce94b5b946889835ebe501b88d0ecf25 SHA512 03c4bd6d985cd8e1d74a417d17debc0c67c99e37b55f688aefbd256930c0b572f098bc656a60bf8d5c31883bb8f1f48465bfcd06b430a363d24383c715e32fd5
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.26.1.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.26.1.ebuild
new file mode 100644
index 000000000000..1ca128492f01
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.26.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.99.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.5
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64"
+IUSE="modemmanager openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.3.0:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	net-misc/networkmanager[teamd=]
+	modemmanager? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+		net-misc/mobile-broadband-provider-info
+	)
+	openconnect? (
+		>=dev-qt/qtxml-${QTMIN}:5
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kquickcharts-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+BDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}/${PN}-5.26.0-unused-dep.patch" )
+
+src_prepare() {
+	ecm_src_prepare
+
+	# TODO: try to get a build switch upstreamed
+	if ! use openconnect; then
+		sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDISABLE_MODEMMANAGER_SUPPORT=$(usex !modemmanager)
+		$(cmake_use_find_package modemmanager KF5ModemManagerQt)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}