kde-plasma/plasma-nm: 5.27.7 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 83 insertions, 0 deletions

diff --git a/kde-plasma/plasma-nm/Manifest b/kde-plasma/plasma-nm/Manifest
index 4015294b3a4a..588da363fbbe 100644
--- a/kde-plasma/plasma-nm/Manifest
+++ b/kde-plasma/plasma-nm/Manifest
@@ -1 +1,2 @@
 DIST plasma-nm-5.27.6.tar.xz 1155340 BLAKE2B bcb9489b458ff9c28b5021fc1e6500c4ac21a68032970275dccf9476d004e617aaf4941dce2e39ea311a0384c74ec4c676d5f9a07922c0f8c5979c8d9771e65d SHA512 16c23f161066c10db8d6eaff6f161a2e1bf0f4d3bd6619b6d7ee9638d84fb48322131974771183bde4a9d29ac98f3fac696d1224b2309a45d1442fdffd20c449
+DIST plasma-nm-5.27.7.tar.xz 1155720 BLAKE2B 2961134be502823bf2111c81917dbf49d2f5a7b44b5ee4421506a9be603e1e7f1f68798e7bbef9e4abdf2003536dc8adbb63442d453a987a0cee5b27786311e8 SHA512 b4b1269de1b4fa2644e27161351b00309c6d03eee752d2b4afe3d1f1bee6f325431d759eca90e7f7f1282a4f2065616bad8c5688759228b9636d969025493b0e
diff --git a/kde-plasma/plasma-nm/plasma-nm-5.27.7.ebuild b/kde-plasma/plasma-nm/plasma-nm-5.27.7.ebuild
new file mode 100644
index 000000000000..b8d087c175c6
--- /dev/null
+++ b/kde-plasma/plasma-nm/plasma-nm-5.27.7.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="true"
+KFMIN=5.106.0
+PVCUT=$(ver_cut 1-3)
+QTMIN=5.15.9
+inherit ecm plasma.kde.org
+
+DESCRIPTION="KDE Plasma applet for NetworkManager"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="openconnect teamd"
+
+DEPEND="
+	>=app-crypt/qca-2.3.0:2[qt5(+)]
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/modemmanager-qt-${KFMIN}:5
+	>=kde-frameworks/networkmanager-qt-${KFMIN}:5[teamd=]
+	>=kde-frameworks/plasma-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	net-misc/mobile-broadband-provider-info
+	net-misc/networkmanager[teamd=]
+	openconnect? (
+		net-vpn/networkmanager-openconnect
+		net-vpn/openconnect:=
+	)
+"
+RDEPEND="${DEPEND}
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+	>=kde-frameworks/kdeclarative-${KFMIN}:5
+	>=kde-frameworks/kirigami-${KFMIN}:5
+	>=kde-frameworks/kquickcharts-${KFMIN}:5
+	>=kde-plasma/kde-cli-tools-${PVCUT}:5
+"
+BDEPEND="
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# TODO: try to get a build switch upstreamed
+	if ! use openconnect; then
+		sed -e "s/^pkg_check_modules.*openconnect/#&/" -i CMakeLists.txt || die
+	fi
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if ! has_version "kde-plasma/plasma-workspace:5"; then
+		elog "${PN} is not terribly useful without kde-plasma/plasma-workspace:5."
+		elog "However, the networkmanagement KCM can be called from either systemsettings"
+		elog "or manually: $ kcmshell5 kcm_networkmanagement"
+	fi
+}