media-libs/waffle: Version bump to 1.7.0

Signed-off-by: Matt Turner <mattst88@gentoo.org>

3 files changed, 69 insertions, 1 deletions

diff --git a/media-libs/waffle/Manifest b/media-libs/waffle/Manifest
index c5a09e0f9baf..648aa7b92f7d 100644
--- a/media-libs/waffle/Manifest
+++ b/media-libs/waffle/Manifest
@@ -1,2 +1,3 @@
 DIST waffle-1.6.1.tar.xz 227152 BLAKE2B 360782636809fa3716589e5c3f2d365ce2a916f3da4dde7ec271ce7e142f94160388f9ae12f1ef0ea79890f45eba9d6ef536e12861ee44cbd88282e3c4f01f52 SHA512 1d5839d517d1067efea163ffd76c05f32f30c3ef0f42dfa1b3a9830d4377829cce368d28889ec5a3be639a5e81db2fb4833d98eafc5ffa5e27578ff11977258f
 DIST waffle-v1.6.2.tar.bz2 259740 BLAKE2B 62708dcda7800d2728ea708f88af5e9c3ff5bbeeef653d064c457ebf86620f67d8dfcd934425810ffb66a452814337e3ed13b6f3e8a4d420363a0b66ceeaf2cf SHA512 2b1e153277366731cb5cb3790c6ae1b884efa8e5e0d5a9499a218f1a902370a066e3253f9922297314943aa751596f70a33faff10c2e480ccc1ceace93ccecbf
+DIST waffle-v1.7.0.tar.bz2 302120 BLAKE2B 8ebfc78182ff86447d88d92edd6452dae28c1515de5f9639c402203bfb5a135bc493040941420161690a4812a202552266bceb89eee948d0c7aeae55d5b8d3d5 SHA512 ee7b8419e309387fa6d610174ba5dddda97525cef41c9600772b902eddfc4570e940437596d7fb50ee9dc2f5945e723236b61463975d2b9cc0faa150696d24c2
diff --git a/media-libs/waffle/waffle-1.7.0.ebuild b/media-libs/waffle/waffle-1.7.0.ebuild
new file mode 100644
index 000000000000..a3d7588a87d7
--- /dev/null
+++ b/media-libs/waffle/waffle-1.7.0.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+if [[ ${PV} = *9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/mesa/${PN}"
+	GIT_ECLASS="git-r3"
+else
+	SRC_URI="https://gitlab.freedesktop.org/mesa/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2"
+	KEYWORDS="amd64 arm ~arm64 ~ppc ~ppc64 x86"
+	S="${WORKDIR}"/${PN}-v${PV}
+fi
+inherit meson multilib-minimal ${GIT_ECLASS}
+
+DESCRIPTION="Library that allows selection of GL API and of window system at runtime"
+HOMEPAGE="http://www.waffle-gl.org/ https://gitlab.freedesktop.org/mesa/waffle"
+
+LICENSE="BSD-2"
+SLOT="0"
+IUSE="doc +egl +gbm wayland X"
+RESTRICT="test" # gl_basic tests don't work when run from portage
+
+RDEPEND="
+	>=media-libs/mesa-9.1.6[egl?,gbm?,${MULTILIB_USEDEP}]
+	>=virtual/opengl-7.0-r1[${MULTILIB_USEDEP}]
+	>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+	>=x11-libs/libxcb-1.9.1[${MULTILIB_USEDEP}]
+	gbm? ( >=virtual/libudev-208:=[${MULTILIB_USEDEP}] )
+	wayland? ( >=dev-libs/wayland-1.10[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=x11-base/xcb-proto-1.8-r3[${MULTILIB_USEDEP}]
+"
+BDEPEND="
+	dev-libs/libxslt
+	app-text/docbook-xml-dtd:4.2
+"
+
+MULTILIB_CHOST_TOOLS=(
+	/usr/bin/wflinfo$(get_exeext)
+)
+
+multilib_src_configure() {
+	local emesonargs=(
+		$(meson_feature X glx)
+		$(meson_feature wayland)
+		$(meson_feature X x11_egl)
+		$(meson_feature gbm)
+		$(meson_feature egl surfaceless_egl)
+		-Dbuild-manpages=$(multilib_is_native_abi && echo true || echo false)
+		-Dbuild-tests=false
+	)
+	meson_src_configure
+}
+
+multilib_src_compile() {
+	meson_src_compile
+}
+
+multilib_src_install() {
+	meson_src_install
+
+	! use doc && rm -rf \
+		"${D}"/usr/share/doc/waffle1 \
+		"${D}"/usr/share/man/man{3,7}
+}
diff --git a/media-libs/waffle/waffle-9999.ebuild b/media-libs/waffle/waffle-9999.ebuild
index 43899a8515c6..a3d7588a87d7 100644
--- a/media-libs/waffle/waffle-9999.ebuild
+++ b/media-libs/waffle/waffle-9999.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7