media-libs/libkate: python-single-r1, EAPI=6

2 files changed, 50 insertions, 56 deletions

diff --git a/media-libs/libkate/libkate-0.4.1-r1.ebuild b/media-libs/libkate/libkate-0.4.1-r1.ebuild
new file mode 100644
index 000000000000..a07d0177b6f7
--- /dev/null
+++ b/media-libs/libkate/libkate-0.4.1-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+inherit python-single-r1
+
+DESCRIPTION="Codec for karaoke and text encapsulation for Ogg"
+HOMEPAGE="https://code.google.com/p/libkate/"
+SRC_URI="https://libkate.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
+IUSE="debug doc wxwidgets"
+
+COMMON_DEPEND="media-libs/libogg:=
+	media-libs/libpng:0="
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+	sys-devel/flex
+	sys-devel/bison
+	doc? ( app-doc/doxygen )"
+RDEPEND="${COMMON_DEPEND}
+	wxwidgets? (
+		${PYTHON_DEPS}
+		=dev-python/wxpython-2.8*[${PYTHON_USEDEP}]
+		media-libs/liboggz )"
+
+REQUIRED_USE="wxwidgets? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use wxwidgets && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	if ! use wxwidgets; then
+		sed -i -e "s/HAVE_PYTHON=yes/HAVE_PYTHON=no/" configure || die
+	fi
+
+	econf $(use_enable debug) $(use_enable doc)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog README
+	use wxwidgets && python_fix_shebang "${D}"
+}
diff --git a/media-libs/libkate/libkate-0.4.1.ebuild b/media-libs/libkate/libkate-0.4.1.ebuild
deleted file mode 100644
index e306f19c49d3..000000000000
--- a/media-libs/libkate/libkate-0.4.1.ebuild
+++ /dev/null
@@ -1,56 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Id$
-
-EAPI="4"
-PYTHON_DEPEND="wxwidgets? 2"
-inherit python
-
-DESCRIPTION="Codec for karaoke and text encapsulation for Ogg"
-HOMEPAGE="https://code.google.com/p/libkate/"
-SRC_URI="https://libkate.googlecode.com/files/${P}.tar.gz"
-
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
-IUSE="debug doc wxwidgets"
-
-COMMON_DEPEND="media-libs/libogg
-	media-libs/libpng"
-DEPEND="${COMMON_DEPEND}
-	virtual/pkgconfig
-	sys-devel/flex
-	sys-devel/bison
-	doc? ( app-doc/doxygen )"
-RDEPEND="${COMMON_DEPEND}
-	wxwidgets? ( =dev-python/wxpython-2.8* media-libs/liboggz )"
-
-pkg_setup() {
-	if use wxwidgets; then
-		python_set_active_version 2
-		python_pkg_setup
-	fi
-}
-
-src_prepare() {
-	use wxwidgets && python_clean_py-compile_files
-}
-
-src_configure() {
-	use wxwidgets || sed -i -e "s/HAVE_PYTHON=yes/HAVE_PYTHON=no/" configure
-	econf $(use_enable debug) $(use_enable doc) --docdir=/usr/share/doc/${PF}
-}
-
-src_install() {
-	emake DESTDIR="${D}" install || die "make install failed"
-	dodoc AUTHORS ChangeLog README
-	use wxwidgets && python_convert_shebangs -r 2 "${D}"
-}
-
-pkg_postinst() {
-	use wxwidgets && python_mod_optimize kdj
-}
-
-pkg_postrm() {
-	use wxwidgets && python_mod_cleanup kdj
-}