media-libs/sdl2-mixer: add 2.6.2

Closes: https://bugs.gentoo.org/881121
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 103 insertions, 0 deletions

diff --git a/media-libs/sdl2-mixer/Manifest b/media-libs/sdl2-mixer/Manifest
index 8fc00617b6a4..61fa0d9c0640 100644
--- a/media-libs/sdl2-mixer/Manifest
+++ b/media-libs/sdl2-mixer/Manifest
@@ -1 +1,2 @@
 DIST SDL2_mixer-2.0.4.tar.gz 11125077 BLAKE2B ccb55020e360fa000e82807b8c4e2371228291943d2dc7371606834ca0f781d4e82581b5427e9902156bf3072208db4ec07e95a06f206e40ff530f432dd9e491 SHA512 98c56069640668aaececa63748de21fc8f243c7d06386c45c43d0ee472bbb2595ccda644d9886ce5b95c3a3dee3c0a96903cf9a89ddc18d38f041133470699a3
+DIST SDL2_mixer-2.6.2.tar.gz 9934376 BLAKE2B 9cf378d03046389b3625b90ca7a4c34d9b80e0908bccef454adedc21f16f24d99acc0fc3522ba981be89d8c58c7a6e877e7d98c798b157529e2cb26141faec8c SHA512 16baa9d8b345bf0224538cbfb2ae9fc5d3deea2b454f41a98006c938fe7a65d5a8c84e28a76f98a4dd971c4fe5cf0219d8bf73331cf11f2702e01600eb197658
diff --git a/media-libs/sdl2-mixer/sdl2-mixer-2.6.2.ebuild b/media-libs/sdl2-mixer/sdl2-mixer-2.6.2.ebuild
new file mode 100644
index 000000000000..ad55760aeb5b
--- /dev/null
+++ b/media-libs/sdl2-mixer/sdl2-mixer-2.6.2.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_P="SDL2_mixer-${PV}"
+inherit multilib-minimal
+
+DESCRIPTION="Simple Direct Media Layer Mixer Library"
+HOMEPAGE="https://github.com/libsdl-org/SDL_mixer"
+SRC_URI="https://www.libsdl.org/projects/SDL_mixer/release/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="ZLIB"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="flac fluidsynth midi mod mp3 opus playtools static-libs timidity tremor vorbis +wav"
+REQUIRED_USE="
+	midi? ( || ( timidity fluidsynth ) )
+	timidity? ( midi )
+	fluidsynth? ( midi )
+	tremor? ( vorbis )
+"
+
+RDEPEND="
+	>=media-libs/libsdl2-2.0.7[${MULTILIB_USEDEP}]
+	flac? ( >=media-libs/flac-1.2.1-r5:=[${MULTILIB_USEDEP}] )
+	midi? (
+		fluidsynth? ( >=media-sound/fluidsynth-1.1.6-r1:=[${MULTILIB_USEDEP}] )
+		timidity? ( media-sound/timidity++ )
+	)
+	mod? ( >=media-libs/libmodplug-0.8.8.4-r1[${MULTILIB_USEDEP}] )
+	mp3? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	opus? ( >=media-libs/opusfile-0.2 )
+	vorbis? (
+		tremor? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+		!tremor? (
+			>=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}]
+			>=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	)
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		$(use_enable static-libs static)
+		--disable-sdltest
+		--enable-music-cmd
+		$(use_enable wav music-wave)
+		$(use_enable mod music-mod)
+		$(use_enable mod music-mod-modplug)
+		--disable-music-mod-modplug-shared
+		$(use_enable midi music-midi)
+		$(use_enable timidity music-midi-timidity)
+		$(use_enable fluidsynth music-midi-fluidsynth)
+		--disable-music-midi-fluidsynth-shared
+		$(use_enable vorbis music-ogg)
+		$(use_enable tremor music-ogg-tremor)
+		--disable-music-ogg
+		$(use_enable flac music-flac)
+		--disable-music-flac
+		$(use_enable mp3 music-mp3)
+		$(use_enable mp3 music-mp3-mpg123)
+		--disable-music-mp3-mpg123-shared
+		$(use_enable opus music-opus)
+		--disable-music-opus-shared
+	)
+
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	if multilib_is_native_abi && use playtools ; then
+		emake DESTDIR="${D}" install-bin
+	fi
+}
+
+multilib_src_install_all() {
+	dodoc {CHANGES,README}.txt
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	# bug #412035
+	if use midi && use fluidsynth; then
+		ewarn "FluidSynth support requires you to set the SDL_SOUNDFONTS"
+		ewarn "environment variable to the location of a SoundFont file"
+		ewarn "unless the game or application happens to do this for you."
+		if use timidity; then
+			ewarn "Failing to do so will result in Timidity being used instead."
+		else
+			ewarn "Failing to do so will result in silence."
+		fi
+	fi
+}