media-radio/tucnak: add 4.54

Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

2 files changed, 69 insertions, 0 deletions

diff --git a/media-radio/tucnak/Manifest b/media-radio/tucnak/Manifest
index fe832b49269a..81a314a26047 100644
--- a/media-radio/tucnak/Manifest
+++ b/media-radio/tucnak/Manifest
@@ -1 +1,2 @@
 DIST tucnak-4.52.tar.gz 6684620 BLAKE2B c56949f61b8a0365deec0eab95d68067e5e8674164ad95f83c1b5cb84740af254f559c5158dc3aa8281353f4db2aee8163de1f92a08dc68487a8be0b00619e92 SHA512 bd20d94bc136e0078628b149f70e510027f9482fcdc881856ba13ed29a2c6be2e02c87c1d2fd2b670ecc347e1335378e5dd3aec5efa5db259b2730a13c10f019
+DIST tucnak-4.54.tar.gz 6817558 BLAKE2B 5c0e4730fbf06a249d528979ab89e2fd2b8067c9786b0ebbdebf9bb1592cd43a95f20582da50989eb04ad7953b13b4d3bf214706db464d8a636e88176a7eb607 SHA512 93f174cfe73c4047ad3c067f84ccd09e27a4acdcc91ece85a2b4187ed2b09c26f99321c25381d7932afea3853b6d26fd96c3d6e0447f2035efbd4946c80b979c
diff --git a/media-radio/tucnak/tucnak-4.54.ebuild b/media-radio/tucnak/tucnak-4.54.ebuild
new file mode 100644
index 000000000000..677cbc82d4da
--- /dev/null
+++ b/media-radio/tucnak/tucnak-4.54.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	~dev-libs/libzia-4.54
+	media-libs/libsndfile
+	media-libs/libsdl2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}