media-sound/musescore: removed obsolete 3.6.1

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Miroslav Šulc <fordfrog@gentoo.org>

2 files changed, 0 insertions, 119 deletions

diff --git a/media-sound/musescore/Manifest b/media-sound/musescore/Manifest
index 33839d6ed5ff..04c98330a4d2 100644
--- a/media-sound/musescore/Manifest
+++ b/media-sound/musescore/Manifest
@@ -1,3 +1,2 @@
 DIST MuseScore_General-0.2.0.tar.bz2 35122747 BLAKE2B 7f9cafb7912ab8c977842c51df69506d4ad3d1d37498c856978a2d5ab50a1c4fe9145a4807f8c353e6f14138704abb2bbd70c948f1621b494c6e0458c2df0184 SHA512 69eeb22e8c9d1d393a2af857baeb8e49bf2a492651d18190685c74df84a5f6b424e37077e39d9d69c117c4896ea1fbb857eba25a1fbcb6f98d53f384a55713cc
-DIST musescore-3.6.1.tar.gz 68754499 BLAKE2B 81462d8c1d57af7f58c117cbeda725ab4eb8fb313fb29f95724aaba43bd9879ae7a018c8b5de932ab8b925c4362b855b06508aba28b7c5ae0ca59ec11b2803ad SHA512 8e486ea08f8ad6b8238ca400475b9108955ff200221c9ba694e42e20e373c43f7dfd89933ca3887de26cefa547d0e1d792922c685a9d16eaefc9293f72a6fe2d
 DIST musescore-3.6.2.tar.gz 69077899 BLAKE2B 4562267b2fd6498b0ba1e503a9117c2680035ccdb66f94bbd9b98ef1c37d4f9eb7d8a84cbac7726b67b9c95e4f076aaaf83087f4ded195150c42ec77462d48e8 SHA512 04ff1ddd82358c070640f81bbaa9c47c5da95aa57c56a5d1b975ad984744e0def17d5581da6bbeda1aae1c68470100d104d4f8a39ba33bf37bf8891ffcbf1d6e
diff --git a/media-sound/musescore/musescore-3.6.1.ebuild b/media-sound/musescore/musescore-3.6.1.ebuild
deleted file mode 100644
index db51b9d0df1d..000000000000
--- a/media-sound/musescore/musescore-3.6.1.ebuild
+++ /dev/null
@@ -1,118 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-CMAKE_MAKEFILE_GENERATOR="emake"
-CHECKREQS_DISK_BUILD=3500M
-inherit cmake xdg check-reqs
-
-if [[ ${PV} == "9999" ]]; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/${PN}/MuseScore.git"
-else
-	SRC_URI="https://github.com/musescore/MuseScore/archive/v${PV}.tar.gz -> ${P}.tar.gz"
-	KEYWORDS="amd64 ~arm64 x86"
-	S="${WORKDIR}/MuseScore-${PV}"
-fi
-
-DESCRIPTION="WYSIWYG Music Score Typesetter"
-HOMEPAGE="https://musescore.org/"
-# MuseScore_General-*.tar.bz2 packaged from https://ftp.osuosl.org/pub/musescore/soundfont/MuseScore_General/
-# It has to be repackaged because the files are not versioned, current version can be found in VERSION file there.
-SRC_URI+=" https://dev.gentoo.org/~fordfrog/distfiles/MuseScore_General-0.2.0.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-IUSE="alsa debug jack mp3 osc omr portaudio portmidi pulseaudio +sf3 sfz webengine"
-REQUIRED_USE="portmidi? ( portaudio )"
-
-BDEPEND="
-	dev-qt/linguist-tools:5
-	virtual/pkgconfig
-"
-DEPEND="
-	dev-qt/designer:5
-	dev-qt/qtconcurrent:5
-	dev-qt/qtcore:5
-	dev-qt/qtdeclarative:5
-	dev-qt/qtgui:5
-	dev-qt/qthelp:5
-	dev-qt/qtnetwork:5
-	dev-qt/qtopengl:5
-	dev-qt/qtprintsupport:5
-	dev-qt/qtquickcontrols2:5
-	>=dev-qt/qtsingleapplication-2.6.1_p20171024[X]
-	dev-qt/qtsvg:5
-	dev-qt/qtxml:5
-	dev-qt/qtxmlpatterns:5
-	>=media-libs/freetype-2.5.2
-	media-libs/libsndfile
-	sys-libs/zlib:=
-	alsa? ( >=media-libs/alsa-lib-1.0.0 )
-	jack? ( virtual/jack )
-	mp3? ( media-sound/lame )
-	omr? ( app-text/poppler )
-	portaudio? ( media-libs/portaudio )
-	portmidi? ( media-libs/portmidi )
-	pulseaudio? ( media-sound/pulseaudio )
-	sf3? ( media-libs/libvorbis )
-	webengine? ( dev-qt/qtwebengine:5[widgets] )
-"
-RDEPEND="${DEPEND}"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-3.0.1-man-pages.patch"
-	"${FILESDIR}/${P}-rename-audioitem.patch"
-)
-
-src_unpack() {
-	if [[ ${PV} == "9999" ]]; then
-		git-r3_src_unpack
-		unpack ${A}
-	else
-		default
-	fi
-}
-
-src_prepare() {
-	cmake_src_prepare
-
-	# Move soundfonts to the correct directory
-	mv "${WORKDIR}"/sound/* "${S}"/share/sound/ || die "Failed to move soundfont files"
-}
-
-src_configure() {
-	local mycmakeargs=(
-		-DAEOLUS=OFF # does not compile
-		-DBUILD_ALSA="$(usex alsa)"
-		-DBUILD_CRASH_REPORTER=OFF
-		-DBUILD_JACK="$(usex jack)"
-		-DBUILD_LAME="$(usex mp3)"
-		-DBUILD_PCH=ON
-		-DBUILD_PORTAUDIO="$(usex portaudio)"
-		-DBUILD_PORTMIDI="$(usex portmidi)"
-		-DBUILD_PULSEAUDIO="$(usex pulseaudio)"
-		-DBUILD_SHARED_LIBS=ON
-		-DBUILD_TELEMETRY_MODULE=ON
-		-DBUILD_WEBENGINE="$(usex webengine)"
-		-DCMAKE_SKIP_RPATH=ON
-		-DDOWNLOAD_SOUNDFONT=OFF
-		-DHAS_AUDIOFILE=ON
-		-DOCR=OFF
-		-DOMR="$(usex omr)"
-		-DSOUNDFONT3=ON
-		-DZERBERUS="$(usex sfz)"
-		-DUSE_PATH_WITH_EXPLICIT_QT_VERSION=ON
-		-DUSE_SYSTEM_FREETYPE=ON
-		-DUSE_SYSTEM_POPPLER=ON
-		-DUSE_SYSTEM_QTSINGLEAPPLICATION=ON
-	)
-	cmake_src_configure
-}
-
-src_compile() {
-	cd "${BUILD_DIR}" || die
-	cmake_build -j1 lrelease manpages
-	cmake_src_compile
-}