net-wireless/srslte: bumpish

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Rick Farina <zerochaos@gentoo.org>

2 files changed, 71 insertions, 9 deletions

diff --git a/net-wireless/srslte/srslte-20.04.1.ebuild b/net-wireless/srslte/srslte-20.04.1.ebuild
index 67d1eb85aac4..3d539eb20f59 100644
--- a/net-wireless/srslte/srslte-20.04.1.ebuild
+++ b/net-wireless/srslte/srslte-20.04.1.ebuild
@@ -3,38 +3,46 @@
 
 EAPI=7
 
-inherit cmake-utils vcs-snapshot
-
-MY_PV=${PV//./_}
+inherit cmake
 
 DESCRIPTION="Open source SDR LTE software suite from Software Radio Systems"
 HOMEPAGE="http://www.softwareradiosystems.com"
-SRC_URI="https://github.com/srsLTE/srsLTE/archive/release_${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+if [ "${PV}" = "9999" ]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/srsLTE/srsLTE.git"
+else
+	inherit vcs-snapshot
+	#This version has not earned keywords:
+	#https://github.com/srsLTE/srsLTE/issues/526
+	#https://github.com/srsLTE/srsLTE/issues/527
+	#KEYWORDS="~amd64 ~x86"
+	MY_PV=${PV//./_}
+	SRC_URI="https://github.com/srsLTE/srsLTE/archive/release_${MY_PV}.tar.gz -> ${P}.tar.gz"
+fi
 
 LICENSE="GPL-3"
 SLOT="0"
-KEYWORDS="~amd64 ~x86"
 IUSE="bladerf simcard soapysdr uhd zeromq"
 
 DEPEND="
 	dev-libs/boost
 	dev-libs/libconfig
 	net-misc/lksctp-tools
-	net-libs/mbedtls
+	net-libs/mbedtls:=
 	sci-libs/fftw:*
 	bladerf? ( net-wireless/bladerf:= )
 	simcard? ( sys-apps/pcsc-lite )
 	soapysdr? ( net-wireless/soapysdr:= )
 	uhd? ( net-wireless/uhd:= )
 	zeromq? ( net-libs/zeromq )
-
 "
 RDEPEND="${DEPEND}"
 BDEPEND=""
 
 src_prepare() {
 	sed -i '/ -Werror"/d' CMakeLists.txt || die
-	cmake-utils_src_prepare
+	cmake_src_prepare
 }
 
 src_configure() {
@@ -45,5 +53,5 @@ src_configure() {
 		-DENABLE_ZEROMQ="$(usex zeromq)"
 		-DENABLE_HARDSIM="$(usex simcard)"
 	)
-	cmake-utils_src_configure
+	cmake_src_configure
 }
diff --git a/net-wireless/srslte/srslte-9999.ebuild b/net-wireless/srslte/srslte-9999.ebuild
new file mode 100644
index 000000000000..2fbb75471979
--- /dev/null
+++ b/net-wireless/srslte/srslte-9999.ebuild
@@ -0,0 +1,54 @@
+# Copyright 2019-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="Open source SDR LTE software suite from Software Radio Systems"
+HOMEPAGE="http://www.softwareradiosystems.com"
+
+if [ "${PV}" = "9999" ]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/srsLTE/srsLTE.git"
+else
+	inherit vcs-snapshot
+	KEYWORDS="~amd64 ~x86"
+	MY_PV=${PV//./_}
+	SRC_URI="https://github.com/srsLTE/srsLTE/archive/release_${MY_PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="bladerf simcard soapysdr uhd zeromq"
+
+DEPEND="
+	dev-libs/boost
+	dev-libs/libconfig
+	net-misc/lksctp-tools
+	net-libs/mbedtls:=
+	sci-libs/fftw:*
+	bladerf? ( net-wireless/bladerf:= )
+	simcard? ( sys-apps/pcsc-lite )
+	soapysdr? ( net-wireless/soapysdr:= )
+	uhd? ( net-wireless/uhd:= )
+	zeromq? ( net-libs/zeromq )
+"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+src_prepare() {
+	sed -i '/ -Werror"/d' CMakeLists.txt || die
+	cmake_src_prepare
+}
+
+src_configure() {
+	mycmakeargs=(
+		-DENABLE_UHD="$(usex uhd)"
+		-DENABLE_BLADERF="$(usex bladerf)"
+		-DENABLE_SOAPYSDR="$(usex soapysdr)"
+		-DENABLE_ZEROMQ="$(usex zeromq)"
+		-DENABLE_HARDSIM="$(usex simcard)"
+	)
+	cmake_src_configure
+}