sys-cluster/rdma-core: add 43.0

Signed-off-by: Florian Schmaus <flow@gentoo.org>

2 files changed, 104 insertions, 0 deletions

diff --git a/sys-cluster/rdma-core/Manifest b/sys-cluster/rdma-core/Manifest
index 68b85d268b83..da9c5078afd3 100644
--- a/sys-cluster/rdma-core/Manifest
+++ b/sys-cluster/rdma-core/Manifest
@@ -1,2 +1,3 @@
 DIST rdma-core-41.0.tar.gz 1784540 BLAKE2B 3c153dcc3563427f32fa32d9a31527635c6bb3e63297c201f30de1328a68ac73ecb3af89074dfcc27d92c640d14d8d8ec61c001659d18336a4156cf8ed22996c SHA512 d8c1210ca078ea53879cee42c838cc88bcc98430471ae609d8c4a25218dbfd63a70f5bbd4e9ba6efabdfc467f7d5796ce618ec22013d414f17502d1257601a80
 DIST rdma-core-42.0.tar.gz 1894415 BLAKE2B 953103beffd1410272dc9abf00f7cb0e900c2dd66a97cefc476fee303e4dfcdf00e9a452ec13a3f199bb34662cbdc50675ce54b6af26991cb9e673cb0d55cb3b SHA512 9e497d3a23bcd72828a717b59016fe25c88b4ec389e166936410c53dac0c6d6d2f45a76eaec18383ab3ca1a11d1b978b19247a3b7cfb121047d3891288a8c38e
+DIST rdma-core-43.0.tar.gz 1905196 BLAKE2B 96003e32de43e3f72a28c5d2d9bc670a709b25caba6ff25a36dedc003daa315b0fbfba1a25084160e659a1f0f7aa8fe32b63b0eb29103624a9499c05ebba0a87 SHA512 d5c48cfe10af40bc1caaed48fd6f82acfee5a22e1bfcc6955098ff328c1833e5455140e8f39cd5ceaa03f0aaa2bc627d56b2c1d3af8f2f505dda8a58ea70b597
diff --git a/sys-cluster/rdma-core/rdma-core-43.0.ebuild b/sys-cluster/rdma-core/rdma-core-43.0.ebuild
new file mode 100644
index 000000000000..07c5665528d4
--- /dev/null
+++ b/sys-cluster/rdma-core/rdma-core-43.0.ebuild
@@ -0,0 +1,103 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit cmake perl-functions python-single-r1 udev systemd
+
+DESCRIPTION="Userspace components for the Linux Kernel's drivers/infiniband subsystem"
+HOMEPAGE="https://github.com/linux-rdma/rdma-core"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/linux-rdma/rdma-core"
+else
+	SRC_URI="https://github.com/linux-rdma/rdma-core/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+
+LICENSE="|| ( GPL-2 ( CC0-1.0 MIT BSD BSD-with-attribution ) )"
+SLOT="0"
+IUSE="neigh python static-libs systemd valgrind"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+COMMON_DEPEND="
+	dev-lang/perl
+	virtual/libudev:=
+	neigh? ( dev-libs/libnl:3 )
+	systemd? ( sys-apps/systemd:= )
+	valgrind? ( dev-util/valgrind )
+	python? ( ${PYTHON_DEPS} )"
+DEPEND="${COMMON_DEPEND}
+	python? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		')
+	)"
+RDEPEND="${COMMON_DEPEND}
+	!sys-fabric/infiniband-diags
+	!sys-fabric/libibverbs
+	!sys-fabric/librdmacm
+	!sys-fabric/libibumad
+	!sys-fabric/ibacm
+	!sys-fabric/libibmad
+	!sys-fabric/srptools
+	!sys-fabric/infinipath-psm
+	!sys-fabric/libcxgb3
+	!sys-fabric/libcxgb4
+	!sys-fabric/libmthca
+	!sys-fabric/libmlx4
+	!sys-fabric/libmlx5
+	!sys-fabric/libocrdma
+	!sys-fabric/libnes"
+# python is required unconditionally at build-time
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-39.0-RDMA_BuildType.patch )
+
+src_configure() {
+	perl_set_version
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_RUNDIR=/run
+		-DCMAKE_INSTALL_SHAREDSTATEDIR="${EPREFIX}"/var/lib
+		-DCMAKE_INSTALL_PERLDIR="${VENDOR_LIB}"
+		-DCMAKE_INSTALL_UDEV_RULESDIR="${EPREFIX}$(get_udevdir)"/rules.d
+		-DCMAKE_INSTALL_SYSTEMD_SERVICEDIR="$(systemd_get_systemunitdir)"
+		-DCMAKE_DISABLE_FIND_PACKAGE_Systemd="$(usex !systemd)"
+		-DENABLE_VALGRIND="$(usex valgrind)"
+		-DENABLE_RESOLVE_NEIGH="$(usex neigh)"
+		-DENABLE_STATIC="$(usex static-libs)"
+		-DNO_PYVERBS="$(usex !python)"
+		-DNO_MAN_PAGES=1
+		-DPYTHON_EXECUTABLE="${PYTHON}"
+	)
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	udev_dorules "${ED}"/usr/share/doc/${PF}/70-persistent-ipoib.rules
+
+	if use neigh; then
+		newinitd "${FILESDIR}"/ibacm.init ibacm
+		newinitd "${FILESDIR}"/iwpmd.init iwpmd
+	fi
+
+	newinitd "${FILESDIR}"/srpd.init srpd
+
+	use python && python_optimize
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}