sys-kernel/gentoo-kernel-bin: add 5.14.14-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index 5871d14ef1a8..33e61d2a6414 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -88,6 +88,7 @@ DIST gentoo-kernel-5.14.13-1.amd64.xpak 68024577 BLAKE2B a43710471bae30805de6110
 DIST gentoo-kernel-5.14.13-1.arm64.xpak 63344405 BLAKE2B bf8618ff4614665383768fe5cacf19277e6283d6c84893a4e4c05b55cde8212c019c9a278044146fb3aa7b52c69f74c94c614e40b1b8fe59f2cc76662ae357ca SHA512 029c1b07c39ea2d95075da59460a864bfb2767675cedd4f1bafefbd61fd084c1d9ad8f3cc579e772581c66b78af44ee386b6e2839e788bb62b45a49557d4b56e
 DIST gentoo-kernel-5.14.13-1.x86.xpak 59170584 BLAKE2B a24893477ab57d178622f1044cc43b136cd12b7814bff1b956c0c1a7a34195bc0d00e6947fd7e0e22ca82b7ef808b164f1577604a373e96a614be4e56d46899e SHA512 d26a623023f79c14964b8a900640e68a870bf3a920cccbe6a9b4d172414411d805eaf6336cdc6a8a4b205b128c08d1c1d9a5953bf8a99a4093dc43d6dcdf3951
 DIST gentoo-kernel-5.14.14-1.amd64.xpak 68060210 BLAKE2B 979f550a50ff3a47e816ea61b5da162bd529a2b622950fea92ce2fd042afc5848468674a02b4b5eb94bcca40055270688f7fe20932708b777351d62bbae498fd SHA512 db752a617cbf86a0b483a2906765198c2b72bffd0a9b146a7ae751c48ca7f600352b173c0574b3ca71e9077183cb92f2b53b63d594d9f355677d1a4b63fc2cc4
+DIST gentoo-kernel-5.14.14-1.arm64.xpak 62976292 BLAKE2B 53877eabafaf39f7d1d6024e7dc3cdf07e78b3a94850f1765763b3f5041fb132d3d7d97a3f6b64cf5ad24195064de933a4e8dab62faf7c843d480f8c0c72bde9 SHA512 f4edba153fe521a5b358114c4faf84b1799ffbb5432b2a72d1f07c70b76f354169ae80e7052e6a6b725698be815073c902b91cc4c5f5fb64b8c5773b7e98dc9a
 DIST gentoo-kernel-5.14.14-1.x86.xpak 59175659 BLAKE2B 4233bbbca15ceac5a1b1e6880eb77f0838a7c6244d8f9ede2e5057c97c80b317572af6b076a51bd32f16bd4640c61cc3c5ef7c92f78d0f499372975b6fdfc2f1 SHA512 79fc5ca7ce6c6c9a06c48e0857e4d0a964f8d8ea42a48b4f336ac5b017bd3a8aadda7ad6dbdc2984ba8ff2b748df386e2b81240da20a55194947902485dce790
 DIST gentoo-kernel-5.14.7-1.amd64.xpak 68031586 BLAKE2B 7cc01200f01a93daf5f0c84b09e066474dc5dcef76ddadf5e43843a3bb8a69710134ee9546cbfc6da0149b96e480d59cc0ceb610608c7e6710dccbb9e9e185f2 SHA512 595ce0155ef9df5809d7c27ee310d3978bde477e6778468f467c9f07a60c43dd7ce6e39320d3e298639f01c18cfed5811de480d0afd884586d13f434c533fe6b
 DIST gentoo-kernel-5.14.7-1.arm64.xpak 63383693 BLAKE2B d8780cdd6306f36530d82b9a5b6a74e1d2caf9c4e9db31d6816020bc9415fe92891e418dd08f89628f3d36189c84f97c10b570091c2d1a94a494f37a21286706 SHA512 90ef111ef0ef68dd362c458c9e6ea15959713118787ebd8c68492bd204da83a212e5def456fd550c3f175565c262581855599adeb34692c65f54c2f2d7f1d06c
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.14-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.14-r1.ebuild
new file mode 100644
index 000000000000..acaaf28e30cb
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.14.14-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}