sys-kernel/gentoo-kernel-bin: bump to 5.12.18-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 116 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index a383135878b3..c340f148bcad 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -69,6 +69,7 @@ DIST gentoo-kernel-5.12.17-1.amd64.xpak 66386296 BLAKE2B d3295c68205b40db976ab8a
 DIST gentoo-kernel-5.12.17-1.arm64.xpak 59979517 BLAKE2B 8fdb4bd2ad39ccbd9a4176c5a1154eabcd8ba94eed84d497ef69fe280aecf8dbb2031a15b54974fc94497a35c94712e0a3ccf9bb38fc868211753161b0eec3c9 SHA512 f9fe1524596a0d9c5fc1cbf5985480c53412605ead30254bc17696fe7807b7c9feeb84c86e44fabe015013be6efa8848303b1a35f53af662369023e3a29203fe
 DIST gentoo-kernel-5.12.17-1.x86.xpak 58117300 BLAKE2B eecdaefb730a38d2b4b5d02dd880f03c841694fea4f940de0dbea28bbf3539b24e34eea97d11adbcd68f709d7d8b1663ab0efa587b6ca163f68a2caf7b04368f SHA512 2d8e4b3beafcae99ade25195a45ab26305e8f600be33992357678e31c3e0304e6812f79894a705d72e418fde7825f50ca905e92b559e4d392f151b776ca1aabd
 DIST gentoo-kernel-5.12.18-1.amd64.xpak 66375757 BLAKE2B ef75d22524ff3b30c93da5d69e1a5484f6fa7f8cfc9fa24dcd88020c58a63ace0fe908b25b52e8a897267286e13f19099c2c58d89e2e5f5c717ce36397daa74d SHA512 5ea36ebaed95ef9f15fb5a104783d91a47951630698e1f505f50804aba2b1927d92f2b89b189adf4bbf8e9e9e76dcc39c4c2b71b54db8e6eaf1ca955d64be8f2
+DIST gentoo-kernel-5.12.18-1.arm64.xpak 60013348 BLAKE2B 859b45c13040f77d96c978a923bfe7a9e41dcffd81ed08baa397fcc68ce7af242b56ce5d288c4615ee2eee59fa0e54de568c9947f12bb58932ba0ae0bd89ddc1 SHA512 4a9e64f385f9d96036486b94ab7e3e6cd809f855ec943576fec51cf8cd4d0a85e600c1a7538f02d98902860958da50b3903b97b6b5964bac4dcbb4851876c237
 DIST gentoo-kernel-5.12.18-1.x86.xpak 58073426 BLAKE2B 50113380cc4c6ba98090675e186b3913d82341389c9cbf5dce0bb10957eabc079d6903eb955fbdd96042f9a330d550603649618162cb60c9ab0017e13c5953c9 SHA512 b7692f7ce78b3b67459fed8a6036b5eadb2107fd1c0c400ab570d4b5f59b3aec69a3ca4609505cab0da1882bdc885ed789cce3b51969816dd7cc1d33727d8572
 DIST gentoo-kernel-5.12.19-1.amd64.xpak 66346655 BLAKE2B a03cbcdcd1a90d48d7e11e988d03efa43980f4d5d8af4b74e4c81f195faa01803af45fb38f7dc1f5af7e9b5338a53bc6f34837c37f7e853c088ec6c1dc084e44 SHA512 3d7f78c488ecee2532f8a8ad61e3aa0f5e238e4cd520d29288715a3dc5c488670d7378f3dc5bc110252dff10108dfbda27a54722c6b044151999428d002b34e1
 DIST gentoo-kernel-5.12.19-1.x86.xpak 58076509 BLAKE2B 0e4aca91c834b23fb169bb6fabab13130de811c15f89e6341ad2a36ac230071ced6c6d7bd30be0f0f3860d09968449c1933cd33ed021213c667304070b80f9a7 SHA512 9786f106ed59661546d9f035e25c39f4c7a4a41f51afa96700867e47bab19e148e8a42c79bc3b7780967c2f82f1fef6920f220fb5fccd6f267a2c6e6a3081126
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.18-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.18-r1.ebuild
new file mode 100644
index 000000000000..9cc54d1c175f
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.12.18-r1.ebuild
@@ -0,0 +1,115 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 1 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)
+"
+
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}