www-client/opera-beta: automated bump (87.0.4390.17)

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 159 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 6ac7968ba4a2..3db4f02afbde 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,4 +1,5 @@
 DIST opera-beta_86.0.4363.12_amd64.deb 84459428 BLAKE2B 3ae8e8ee977143df6dea0f42f2bb8ae840175306fb6db632406e227d3cb895c5f7b845495c95f449d0d6697976c2b50904b9cda1c7f4fa0eea95af95a320bde4 SHA512 49a6240e2a6ee3bcd1effbb5518859209e92864e800b25b247892579dd0891a9cb8f81b32fbce3c229d7529f429ee65c2a1d44cccbe702f2d2325e5a50fbb396
 DIST opera-beta_86.0.4363.15_amd64.deb 84377960 BLAKE2B c50bb3123bf54d38a33791f146c85f6cb5ff0422ac7401468fe3b52a278fb708bfe87f5829b4a44fa46dfcef89abc3cb4e96bf446f82618871c2260d06a0611a SHA512 49e82edbd8a0614566c53fad677753b315ef5b31adc333a34f0d16ce4d572ad6a63571c8b598a69ca24877b1e253ffe928b35cb981764dc09251706d062a55eb
 DIST opera-beta_86.0.4363.17_amd64.deb 84367448 BLAKE2B 2aefc3bd35aa4baed532d33d74a84c97c4e31ddbb92df19231cd5e7dc2b93ae6fcc18c0b138c2270574c3b2ae5077cdf34d3759e652460690295e7c2815990a5 SHA512 caffd09646e30260d56fc865c3df1d2fa3cda1e219a077ac29c889187fb1aedeed2b75f530b6455a10fe5696e341057e8c30df307328abd8a08505c6bd1200db
+DIST opera-beta_87.0.4390.17_amd64.deb 85140936 BLAKE2B 6dadea52293c40ad678c554b7846851f0f210c447c268c8f10f02887edc908ba12b634098e11f2db310cc1a4418ee9d429ace944fb95eea7f51784e59a48d4d9 SHA512 46a8a52b73d36fd7a920124e0af6b98e04eb4884619a805c26cece4ffc57ab4428f3e9ed29ee75d76e226032fd6ccb584074eb2c855509f8858bfbbed06de4cc
 DIST opera-ffmpeg-codecs-100.0.4896.20.tar.xz 1393360 BLAKE2B be608a42042b2713fff66716c171959609e06d94b6c56cd8081e05313915378eff25c7098228ff6727a430c9f02bd4e9c9dcce4e715f09e10ac62d89ccd6ae1c SHA512 7dab4a091ac3562cd9c09cf37bc70edf9000ad1b3d31f27278e2edc68b9f55fd4f821ebc90a761ae5803542195718015c859e107344b31a5f7f9ad6cf028df42
diff --git a/www-client/opera-beta/opera-beta-87.0.4390.17.ebuild b/www-client/opera-beta/opera-beta-87.0.4390.17.ebuild
new file mode 100644
index 000000000000..d1fbcd0074a1
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-87.0.4390.17.ebuild
@@ -0,0 +1,158 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="100.0.4896.20"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs suid"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	app-accessibility/at-spi2-atk:2
+	app-accessibility/at-spi2-core:2
+	dev-libs/atk
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
+}