www-client/uget: version bump to 2.2.1.

Package-Manager: Portage-2.3.40, Repoman-2.3.9
Closes: https://github.com/gentoo/gentoo/pull/9639

1 files changed, 62 insertions, 0 deletions

diff --git a/www-client/uget/uget-2.2.1.ebuild b/www-client/uget/uget-2.2.1.ebuild
new file mode 100644
index 000000000000..1a5a0ce8eda3
--- /dev/null
+++ b/www-client/uget/uget-2.2.1.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit gnome2-utils xdg-utils
+
+DESCRIPTION="Download manager using gtk+ and libcurl"
+HOMEPAGE="http://www.ugetdm.com"
+SRC_URI="mirror://sourceforge/urlget/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="aria2 ayatana control-socket +gnutls gstreamer libnotify nls openssl rss"
+REQUIRED_USE="^^ ( gnutls openssl )"
+
+RDEPEND="
+	>=net-misc/curl-7.19.1
+	dev-libs/libpcre
+	>=dev-libs/glib-2.32:2
+	>=x11-libs/gtk+-3.4:3
+	gnutls? (
+		net-libs/gnutls
+		dev-libs/libgcrypt:0
+	)
+	aria2? ( net-misc/aria2[xmlrpc] )
+	ayatana? ( dev-libs/libappindicator:3 )
+	gstreamer? ( media-libs/gstreamer:1.0 )
+	libnotify? ( x11-libs/libnotify )
+	openssl? ( dev-libs/openssl:0 )
+	"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+	"
+
+src_configure() {
+	local myconf=(
+		$(use_enable ayatana appindicator)
+		$(use_enable control-socket unix_socket)
+		$(use_enable gstreamer)
+		$(use_enable libnotify notify)
+		$(use_enable nls)
+		$(use_enable rss rss_notify)
+		$(use_with gnutls)
+		$(use_with openssl)
+	)
+
+	econf "${myconf[@]}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	gnome2_icon_cache_update
+}