x11-misc/xkeyboard-config: add missing test dependencies

* New revision due to plenty dropped keywords
* pytest-xdist is used if available, make it requirement so that
  everybody benefits.
* Disabled timeout for pytest tests. Observed it already take 40s with
  xdist and a 12 thread cpu, so you can't trust it to not fail due to high
  load congestion.

Closes: https://bugs.gentoo.org/917479
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Closes: https://github.com/gentoo/gentoo/pull/33864
Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 85 insertions, 2 deletions

diff --git a/x11-misc/xkeyboard-config/xkeyboard-config-2.40-r1.ebuild b/x11-misc/xkeyboard-config/xkeyboard-config-2.40-r1.ebuild
new file mode 100644
index 000000000000..a290e8aa2752
--- /dev/null
+++ b/x11-misc/xkeyboard-config/xkeyboard-config-2.40-r1.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..12} )
+inherit meson python-any-r1
+
+DESCRIPTION="X keyboard configuration database"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/XKeyboardConfig https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/xkeyboard-config/xkeyboard-config.git"
+	inherit git-r3
+else
+	SRC_URI="https://www.x.org/releases/individual/data/${PN}/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~m68k ~mips ~ppc ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	dev-lang/perl
+	dev-libs/libxslt
+	sys-devel/gettext
+	test? (
+		${PYTHON_DEPS}
+		x11-apps/xkbcomp
+		x11-libs/libxkbcommon
+		$(python_gen_any_dep '
+			dev-python/pycountry[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/pycountry[${PYTHON_USEDEP}]"
+	python_has_version "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
+	python_has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	eapply_user
+
+	# Remove pytest timeout
+	sed -i -e "/test('pytest'/,/)$/ { s/timeout: [0-9]*/timeout: 0/ }" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dxkb-base="${EPREFIX}/usr/share/X11/xkb"
+		-Dcompat-rules=true
+	)
+	meson_src_configure
+}
diff --git a/x11-misc/xkeyboard-config/xkeyboard-config-9999.ebuild b/x11-misc/xkeyboard-config/xkeyboard-config-9999.ebuild
index 4fcf0d647513..4456bf37dfdd 100644
--- a/x11-misc/xkeyboard-config/xkeyboard-config-9999.ebuild
+++ b/x11-misc/xkeyboard-config/xkeyboard-config-9999.ebuild
@@ -23,19 +23,37 @@ IUSE="test"
 RESTRICT="!test? ( test )"
 
 BDEPEND="
-	${PYTHON_DEPS}
 	dev-lang/perl
 	dev-libs/libxslt
 	sys-devel/gettext
 	test? (
+		${PYTHON_DEPS}
+		x11-apps/xkbcomp
+		x11-libs/libxkbcommon
 		$(python_gen_any_dep '
+			dev-python/pycountry[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
 			dev-python/pytest[${PYTHON_USEDEP}]
 		')
 	)
 "
 
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/pycountry[${PYTHON_USEDEP}]"
+	python_has_version "dev-python/pytest-xdist[${PYTHON_USEDEP}]"
+	python_has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
 pkg_setup() {
-	python-any-r1_pkg_setup
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	eapply_user
+
+	# Remove pytest timeout
+	sed -i -e "/test('pytest'/,/)$/ { s/timeout: [0-9]*/timeout: 0/ }" meson.build || die
 }
 
 src_configure() {