x11-wm/fluxbox: remove live ebuild

Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Mikle Kolyada <zlogene@gentoo.org>

1 files changed, 0 insertions, 110 deletions

diff --git a/x11-wm/fluxbox/fluxbox-9999.ebuild b/x11-wm/fluxbox/fluxbox-9999.ebuild
deleted file mode 100644
index 7cf07c7b7fe9..000000000000
--- a/x11-wm/fluxbox/fluxbox-9999.ebuild
+++ /dev/null
@@ -1,110 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=5
-inherit eutils flag-o-matic toolchain-funcs git-r3 prefix
-
-IUSE="nls xinerama bidi +truetype +imlib +slit +systray +toolbar vim-syntax"
-
-REQUIRED_USE="systray? ( toolbar )"
-
-DESCRIPTION="X11 window manager featuring tabs and an iconbar"
-
-EGIT_REPO_URI="git://git.fluxbox.org/fluxbox.git"
-SRC_URI=""
-HOMEPAGE="http://www.fluxbox.org"
-SLOT="0"
-LICENSE="MIT"
-KEYWORDS=""
-
-RDEPEND="
-	bidi? ( >=dev-libs/fribidi-0.19.2 )
-	imlib? ( >=media-libs/imlib2-1.2.0[X] )
-	truetype? ( media-libs/freetype )
-	vim-syntax? ( app-vim/fluxbox-syntax )
-	x11-libs/libXext
-	x11-libs/libXft
-	x11-libs/libXpm
-	x11-libs/libXrandr
-	x11-libs/libXrender
-	xinerama? ( x11-libs/libXinerama )
-	|| ( x11-misc/gxmessage x11-apps/xmessage )
-"
-DEPEND="
-	${RDEPEND}
-	bidi? ( virtual/pkgconfig )
-	nls? ( sys-devel/gettext )
-	x11-base/xorg-proto
-"
-
-src_prepare() {
-	./autogen.sh
-
-	# We need to be able to include directories rather than just plain
-	# files in menu [include] items. This patch will allow us to do clever
-	# things with style ebuilds.
-	epatch "${FILESDIR}/gentoo_style_location-1.1.x.patch"
-	eprefixify util/fluxbox-generate_menu.in
-
-	epatch "${FILESDIR}"/osx-has-otool.patch
-
-	# Add in the Gentoo -r number to fluxbox -version output.
-	if [[ "${PR}" == "r0" ]] ; then
-		suffix="gentoo"
-	else
-		suffix="gentoo-${PR}"
-	fi
-	sed -i \
-		-e "s~\(__fluxbox_version .@VERSION@\)~\1-${suffix}~" \
-		version.h.in || die "version sed failed"
-}
-
-src_configure() {
-	use bidi && append-cppflags "$($(tc-getPKG_CONFIG) --cflags fribidi)"
-
-	econf $(use_enable bidi fribidi ) \
-		$(use_enable imlib imlib2) \
-		$(use_enable nls) \
-		$(use_enable slit ) \
-		$(use_enable systray) \
-		$(use_enable toolbar ) \
-		$(use_enable truetype xft) \
-		$(use_enable xinerama) \
-		--sysconfdir="${EPREFIX}"/etc/X11/${PN} \
-		--with-style="${EPREFIX}"/usr/share/fluxbox/styles/Emerge
-}
-
-src_compile() {
-	default
-
-	ebegin "Creating a menu file (may take a while)"
-	mkdir -p "${T}/home/.fluxbox" || die "mkdir home failed"
-	# Call fluxbox-generate_menu through bash since it lacks +x
-	# chmod 744 may be an equal fix
-	MENUFILENAME="${S}/data/menu" MENUTITLE="Fluxbox ${PV}" \
-		CHECKINIT="no. go away." HOME="${T}/home" \
-		bash "${S}/util/fluxbox-generate_menu" -is -ds \
-		|| die "menu generation failed"
-	eend $?
-}
-
-src_install() {
-	emake DESTDIR="${D}" STRIP="" install
-	dodoc README* AUTHORS TODO* ChangeLog NEWS
-
-	# Install the generated menu
-	insinto /usr/share/fluxbox
-	doins data/menu
-
-	insinto /usr/share/xsessions
-	doins "${FILESDIR}"/${PN}.desktop
-
-	exeinto /etc/X11/Sessions
-	newexe "${FILESDIR}"/${PN}.xsession fluxbox
-
-	# Styles menu framework
-	insinto /usr/share/fluxbox/menu.d/styles
-	doins "${FILESDIR}"/styles-menu-fluxbox
-	doins "${FILESDIR}"/styles-menu-commonbox
-	doins "${FILESDIR}"/styles-menu-user
-}