1 files changed, 47 insertions, 0 deletions
diff --git a/dev-libs/libbson/libbson-0.98.0.ebuild b/dev-libs/libbson/libbson-0.98.0.ebuild
new file mode 100644
index 000000000000..a26025e52779
--- /dev/null
+++ b/dev-libs/libbson/libbson-0.98.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit autotools eutils
+
+DESCRIPTION="A BSON utility library"
+HOMEPAGE="https://github.com/mongodb/libbson"
+SRC_URI="https://github.com/mongodb/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="debug examples static-libs"
+
+RDEPEND=""
+DEPEND="${RDEPEND}"
+
+DOCS=( AUTHORS NEWS README )
+
+src_prepare() {
+	# https://github.com/mongodb/mongo-c-driver/issues/54
+	sed -i -e "s/PTHREAD_LIBS/PTHREAD_CFLAGS/g" src/bson/Makefile.am \
+		tests/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	econf --disable-hardening \
+		--disable-optimizations \
+		$(use_enable debug) \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	doman doc/*.3
+
+	use static-libs || find "${D}" -name '*.la' -delete
+
+	if use examples; then
+		insinto /usr/share/${PF}/examples
+		doins examples/*.c
+	fi
+}