1 files changed, 35 insertions, 0 deletions
diff --git a/dev-libs/libsodium/libsodium-1.0.5.ebuild b/dev-libs/libsodium/libsodium-1.0.5.ebuild
new file mode 100644
index 000000000000..a87bde865f6b
--- /dev/null
+++ b/dev-libs/libsodium/libsodium-1.0.5.ebuild
@@ -0,0 +1,35 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils
+
+DESCRIPTION="A portable fork of NaCl, a higher-level cryptographic library"
+HOMEPAGE="https://github.com/jedisct1/libsodium"
+SRC_URI="http://download.libsodium.org/${PN}/releases/${P}.tar.gz"
+
+LICENSE="ISC"
+SLOT="0/13"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="+asm minimal static-libs +urandom"
+
+src_configure() {
+	local myconf
+
+	# --disable-pie needed on x86, bug #512734
+	use x86 && myconf="${myconf} --disable-pie"
+
+	econf \
+		$(use_enable asm) \
+		$(use_enable minimal) \
+		$(use_enable !urandom blocking-random) \
+		$(use_enable static-libs static) \
+		${myconf}
+}
+
+src_install() {
+	default
+	prune_libtool_files
+}