app-misc/srm/srm-1.2.15.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools flag-o-matic

DESCRIPTION="A command-line compatible rm which destroys file contents before unlinking"
HOMEPAGE="https://sourceforge.net/projects/srm/"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ppc ~ppc64 x86"
IUSE="debug"

DEPEND="sys-kernel/linux-headers"

PATCHES=(
	"${FILESDIR}"/${PN}-1.2.15-cflags.patch
	"${FILESDIR}"/${PN}-1.2.15-musl.patch
)

src_prepare() {
	default
	eautoreconf
}

src_configure() {
	# enable the sighandler_t decl on glibc and musl
	append-cppflags -D_GNU_SOURCE
	econf $(use_enable debug)
}

pkg_postinst() {
	ewarn "Please note that srm will not work as expected with any journaled file"
	ewarn "system (e.g., reiserfs, ext3)."
	ewarn "See: ${EROOT}/usr/share/doc/${PF}/README"
}