blob: 328515ace716c165f3de189760b5dedd767d6002 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit multibuild cmake
DESCRIPTION="Excel file(*.xlsx) reader/writer library using Qt"
HOMEPAGE="https://github.com/QtExcel/QXlsx"
SRC_URI="https://github.com/QtExcel/QXlsx/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="MIT"
# soversion
SLOT="0/0.1.4.4"
KEYWORDS="amd64 ppc ppc64 ~riscv x86"
IUSE="+qt5 qt6"
REQUIRED_USE="|| ( qt5 qt6 )"
RDEPEND="
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5=
)
qt6? (
dev-qt/qtbase:6=[gui]
)
"
DEPEND="${RDEPEND}"
S="${WORKDIR}/QXlsx-${PV}/QXlsx"
pkg_setup() {
MULTIBUILD_VARIANTS=( $(usev qt5) $(usev qt6) )
}
src_configure() {
my_src_configure() {
local mycmakeargs=(
-DQT_VERSION_MAJOR="${MULTIBUILD_VARIANT/qt/}"
)
cmake_src_configure
}
multibuild_foreach_variant my_src_configure
}
src_compile() {
multibuild_foreach_variant cmake_src_compile
}
src_install() {
multibuild_foreach_variant cmake_src_install
}
|
GitWeb
