dev-python/pyjwt/pyjwt-1.7.1-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{7..9} pypy3 )

inherit distutils-r1 optfeature

MY_PN="PyJWT"
DESCRIPTION="JSON Web Token implementation in Python"
HOMEPAGE="https://github.com/progrium/pyjwt https://pypi.org/project/PyJWT/"
SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
S="${WORKDIR}"/${MY_PN}-${PV}

LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ppc ~ppc64 sparc x86 ~amd64-linux ~x86-linux"

RDEPEND=""
DEPEND="
	test? (
		>=dev-python/cryptography-1.4.0[${PYTHON_USEDEP}]
	)"

distutils_enable_tests pytest

python_prepare_all() {
	find . -name '__pycache__' -prune -exec rm -rf {} + || die
	find . -name '*.pyc' -delete || die

	# enables coverage, we don't need that
	rm setup.cfg || die
	# kill tests using pycrypto that break with pycryptodome
	sed -i -e '/has_pycrypto/s:True:False:' \
		tests/contrib/test_algorithms.py || die

	local PATCHES=(
		"${FILESDIR}"/pyjwt-1.7.1-ecdsa-fix.patch
	)

	distutils-r1_python_prepare_all
}

python_test() {
	pytest -vv || die "Tests fail with ${EPYTHON}"
}

pkg_postinst() {
	optfeature "cryptography" dev-python/cryptography
	optfeature "flake8" dev-python/flake8{,-import-order}

	ewarn "flake8 feature requires 'pep8-naming' which is not packaged yet"
}