blob: c6f00aa98be96dc7dd97239eef1d5ffbe150e852 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 2020-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson
DESCRIPTION="Liberally licensed VNC server library with a clean interface"
HOMEPAGE="https://github.com/any1/neatvnc/"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/any1/neatvnc.git"
else
SRC_URI="https://github.com/any1/neatvnc/archive/v${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
fi
LICENSE="ISC"
SLOT="0"
IUSE="examples gbm h264 jpeg ssl test tracing"
REQUIRED_USE="h264? ( gbm )"
RESTRICT="!test? ( test )"
RDEPEND="
dev-libs/aml
sys-libs/zlib
x11-libs/pixman
gbm? ( media-libs/mesa )
h264? (
media-video/ffmpeg:=
x11-libs/libdrm
)
jpeg? ( media-libs/libjpeg-turbo:= )
ssl? ( net-libs/gnutls:= )
tracing? ( dev-util/systemtap )
"
DEPEND="
${RDEPEND}
x11-libs/libdrm
"
BDEPEND="
virtual/pkgconfig
"
src_configure() {
local emesonargs=(
$(meson_use examples)
$(meson_use test tests)
$(meson_feature jpeg)
$(meson_feature ssl tls)
$(meson_use tracing systemtap)
$(meson_feature gbm)
$(meson_feature h264)
)
meson_src_configure
}
|
GitWeb
