blob: 8b7771628d25cb52da1588694382fbbf5b6dbd5d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools toolchain-funcs
DESCRIPTION="Tool for computations in affine monoids and more"
HOMEPAGE="https://www.normaliz.uni-osnabrueck.de/"
SRC_URI="https://github.com/Normaliz/Normaliz/releases/download/v${PV}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0/3"
KEYWORDS="~amd64 ~arm ~riscv ~x86 ~amd64-linux ~x86-linux"
IUSE="doc extras nauty openmp"
RDEPEND="
dev-libs/gmp:=[cxx(+)]
nauty? ( sci-mathematics/nauty )
"
DEPEND="
${RDEPEND}
dev-libs/boost
"
# Only a boost header is needed -> not RDEPEND
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
src_prepare() {
# Fix C standard compliance.
default
eautoreconf
}
src_configure() {
# flint (and arb, which doesn't make an appearance in ./configure --help)
# is somehow connected to e-antic, which we do not yet package. Likewise
# we have no packages for cocoalib or hashlibrary.
econf \
$(use_enable openmp) \
$(use_with nauty) \
--without-cocoalib \
--without-hashlibrary \
--without-flint \
--without-e-antic \
--disable-static
}
src_compile() {
# Clobber the default "AM_LDFLAGS = -Wl,-s" to avoid QA warnings
# about pre-stripped binaries.
emake AM_LDFLAGS=""
}
src_install() {
default
use doc && dodoc doc/Normaliz.pdf doc/NmzShortRef.pdf
if use extras; then
newdoc Singular/normaliz.pdf singular-normaliz.pdf
insinto /usr/share/${PN}
doins Singular/normaliz.lib
doins Macaulay2/Normaliz.m2
fi
find "${ED}" -type f -name "*.la" -delete || die
}
|
GitWeb
