x11-plugins/pidgin-musictracker/pidgin-musictracker-0.4.22.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

inherit autotools

DESCRIPTION="A Pidgin now playing plugin to publicise the songs you are listening"
HOMEPAGE="https://code.google.com/p/pidgin-musictracker/"
SRC_URI="https://pidgin-musictracker.googlecode.com/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 ppc ~riscv x86"
IUSE="debug"

DEPEND="
	dev-libs/dbus-glib
	dev-libs/libpcre
	net-im/pidgin[gtk]"
RDEPEND="${DEPEND}"
BDEPEND="sys-devel/gettext"

PATCHES=( "${FILESDIR}"/${P}-fno-common.patch )

src_prepare() {
	default
	sed -i -e "s/DOMAIN/PACKAGE/g" po/Makefile.in.in || die
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable debug) \
		--disable-werror
}

src_install() {
	default
	find "${ED}" -name '*.la' -delete || die
}