blob: b714dc1a6c5a00f212f5f038773dc312d7c37f60 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
DESCRIPTION="rxvt compatible terminal emulator with transparency support"
HOMEPAGE="http://aterm.sourceforge.net"
SRC_URI="ftp://ftp.afterstep.org/apps/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64"
IUSE="background cjk xgetdefault"
RDEPEND="
media-libs/libjpeg-turbo:0=
media-libs/libpng:0=
background? ( media-libs/libafterimage )
x11-libs/libX11
x11-libs/libXext
x11-libs/libICE
"
DEPEND="${RDEPEND}
x11-base/xorg-proto
x11-libs/libXt
"
PATCHES=(
# Security bug #219746
"${FILESDIR}/${P}-display-security-issue.patch"
"${FILESDIR}/${P}-deadkeys.patch"
"${FILESDIR}/${P}-dpy.patch"
"${FILESDIR}/${P}-remove-streams.patch"
"${FILESDIR}/${P}-configure-clang16.patch"
)
src_prepare() {
default
# fix pre-stripped files
sed -i -e "/INSTALL_PROGRAM/ s:-s::" autoconf/Make.common.in || die "sed Makefile failed"
# Clang 16
sed -i -e 's:configure.in:configure.ac:' Makefile.in || die
cd autoconf || die
mv configure.in configure.ac || die
eautoreconf
}
src_configure() {
local myconf
use cjk && myconf="$myconf
--enable-kanji
--enable-thai
--enable-big5"
case "${CHOST}" in
*-darwin*) myconf="${myconf} --enable-wtmp" ;;
*-interix*) ;;
*) myconf="${myconf} --enable-utmp --enable-wtmp"
esac
econf \
$(use_enable xgetdefault) \
$(use_with background afterimage-config "${EPREFIX}"/usr/bin) \
--with-terminfo="${EPREFIX}"/usr/share/terminfo \
--enable-transparency \
--with-x \
${myconf}
}
src_install() {
emake DESTDIR="${D}" install
fowners root:utmp /usr/bin/aterm
fperms g+s /usr/bin/aterm
doman doc/aterm.1
dodoc ChangeLog doc/FAQ doc/README.*
docinto menu
dodoc doc/menu/*
}
pkg_postinst() {
echo
elog "The transparent background will only work if you have the 'real'"
elog "root wallpaper set. Some tools that might help include:"
elog "wmsetbg (x11-wm/windowmaker), and/or media-gfx/feh."
echo
}
|
GitWeb