clean old python impls, add py3.3 3.4 support, add IUSE test and testrunner dep, upgrade test phase, fixes bug #524246 by W. T. King requesting added py3 support, rm old

Package-Manager: portage-2.2.10/cvs/Linux x86_64
Manifest-Sign-Key: 0xB8072B0D

1 files changed, 55 insertions, 0 deletions

diff --git a/dev-python/execnet/execnet-1.2.0-r1.ebuild b/dev-python/execnet/execnet-1.2.0-r1.ebuild
new file mode 100644
index 000000000000..432948a817e6
--- /dev/null
+++ b/dev-python/execnet/execnet-1.2.0-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/execnet/execnet-1.2.0-r1.ebuild,v 1.1 2014/10/02 10:01:48 idella4 Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="Rapid multi-Python deployment"
+HOMEPAGE="http://codespeak.net/execnet/ http://pypi.python.org/pypi/execnet/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )"
+RDEPEND=""
+
+python_prepare_all() {
+	# Remove doctest that access an i'net sire
+	rm doc/example/test_info.txt || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C doc html
+}
+
+src_test() {
+	# Tests are a bit fragile to failures in parallel.
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+	distutils-r1_src_test
+}
+
+python_test() {
+	# Re-enable in order to properly test disabling it ;).
+	# https://bitbucket.org/hpk42/execnet/issue/10
+	unset PYTHONDONTWRITEBYTECODE
+
+	# https://bitbucket.org/hpk42/execnet/issue/35/test-failures-in-execnet-120
+	py.test || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+
+	distutils-r1_python_install_all
+}