revbump; migrate -> distutils-r1, only the less used kinterbasdb not yet migrated due to its status 'less used'

Package-Manager: portage-2.1.11.63/cvs/Linux x86_64
Manifest-Sign-Key: 0xB8072B0D

1 files changed, 41 insertions, 0 deletions

diff --git a/dev-python/sqlobject/sqlobject-1.4.1-r1.ebuild b/dev-python/sqlobject/sqlobject-1.4.1-r1.ebuild
new file mode 100644
index 000000000000..cc5abbc57e2f
--- /dev/null
+++ b/dev-python/sqlobject/sqlobject-1.4.1-r1.ebuild
@@ -0,0 +1,41 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sqlobject/sqlobject-1.4.1-r1.ebuild,v 1.1 2013/07/03 07:33:03 idella4 Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python{2_5,2_6,2_7} )
+PYTHON_REQ_USE="sqlite?"
+inherit distutils-r1
+
+MY_PN="SQLObject"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Object-Relational Manager, aka database wrapper"
+HOMEPAGE="http://sqlobject.org/ http://pypi.python.org/pypi/SQLObject"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc firebird mysql postgres sqlite"
+
+RDEPEND=">=dev-python/formencode-0.2.2[${PYTHON_USEDEP}]
+		firebird? ( >=dev-python/kinterbasdb-3.0.2 )
+		mysql? ( >=dev-python/mysql-python-0.9.2-r1[${PYTHON_USEDEP}] )
+		postgres? ( dev-python/psycopg[${PYTHON_USEDEP}] )"
+DEPEND="${RDEPEND}
+		dev-python/setuptools[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/${MY_P}"
+
+python_install_all() {
+	if use doc; then
+		pushd docs
+		dodoc *.txt || die "dodoc failed"
+		dohtml -r presentation-2004-11 || die "dohtml failed"
+		insinto /usr/share/doc/${PF}
+		doins -r europython || die "doins failed"
+		popd
+	fi
+	distutils-r1_python_install_all
+}