Version bump. Switch to out-of-source build.

Package-Manager: portage-2.2.0_alpha101/cvs/Linux x86_64

2 files changed, 130 insertions, 1 deletions

diff --git a/dev-python/pyside/ChangeLog b/dev-python/pyside/ChangeLog
index 09cc2916ffc6..3ad475608dfc 100644
--- a/dev-python/pyside/ChangeLog
+++ b/dev-python/pyside/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/pyside
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/ChangeLog,v 1.30 2012/04/22 12:17:30 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/ChangeLog,v 1.31 2012/04/28 17:45:03 pesa Exp $
+
+*pyside-1.1.1 (28 Apr 2012)
+
+  28 Apr 2012; Davide Pesavento <pesa@gentoo.org> +pyside-1.1.1.ebuild:
+  Version bump. Switch to out-of-source build.
 
   22 Apr 2012; Markus Meier <maekke@gentoo.org> pyside-1.1.0-r1.ebuild:
   x86 stable, bug #401789
diff --git a/dev-python/pyside/pyside-1.1.1.ebuild b/dev-python/pyside/pyside-1.1.1.ebuild
new file mode 100644
index 000000000000..880345231c5f
--- /dev/null
+++ b/dev-python/pyside/pyside-1.1.1.ebuild
@@ -0,0 +1,124 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pyside/pyside-1.1.1.ebuild,v 1.1 2012/04/28 17:45:03 pesa Exp $
+
+EAPI=4
+
+PYTHON_DEPEND="2:2.6 3:3.2"
+SUPPORT_PYTHON_ABIS="1"
+RESTRICT_PYTHON_ABIS="2.4 2.5 3.1 *-jython 2.7-pypy-*"
+
+VIRTUALX_COMMAND="cmake-utils_src_test"
+
+inherit multilib cmake-utils python virtualx
+
+MY_P="${PN}-qt4.8+${PV}"
+
+DESCRIPTION="Python bindings for the Qt framework"
+HOMEPAGE="http://www.pyside.org/"
+SRC_URI="http://www.pyside.org/files/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X declarative help multimedia kde opengl phonon script scripttools sql svg test webkit xmlpatterns"
+
+REQUIRED_USE="
+	declarative? ( X )
+	help? ( X )
+	multimedia? ( X )
+	opengl? ( X )
+	phonon? ( X )
+	scripttools? ( X script )
+	sql? ( X )
+	svg? ( X )
+	test? ( X )
+	webkit? ( X )
+"
+
+QT_PV="4.7.0:4"
+
+RDEPEND="
+	>=dev-python/shiboken-${PV}
+	>=x11-libs/qt-core-${QT_PV}
+	X? (
+		>=x11-libs/qt-gui-${QT_PV}[accessibility]
+		>=x11-libs/qt-test-${QT_PV}
+	)
+	declarative? ( >=x11-libs/qt-declarative-${QT_PV} )
+	help? ( >=x11-libs/qt-assistant-${QT_PV} )
+	multimedia? ( >=x11-libs/qt-multimedia-${QT_PV} )
+	opengl? ( >=x11-libs/qt-opengl-${QT_PV} )
+	phonon? (
+		kde? ( media-libs/phonon )
+		!kde? ( || (
+			>=x11-libs/qt-phonon-${QT_PV}
+			media-libs/phonon
+		) )
+	)
+	script? ( >=x11-libs/qt-script-${QT_PV} )
+	sql? ( >=x11-libs/qt-sql-${QT_PV} )
+	svg? ( >=x11-libs/qt-svg-${QT_PV}[accessibility] )
+	webkit? ( >=x11-libs/qt-webkit-${QT_PV} )
+	xmlpatterns? ( >=x11-libs/qt-xmlpatterns-${QT_PV} )
+"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}
+
+DOCS=( ChangeLog )
+
+src_prepare() {
+	# Fix generated pkgconfig file to require the shiboken
+	# library suffixed with the correct python version.
+	sed -i -e '/^Requires:/ s/shiboken$/&@SHIBOKEN_PYTHON_SUFFIX@/' \
+		libpyside/pyside.pc.in || die
+}
+
+src_configure() {
+	configuration() {
+		local mycmakeargs=(
+			-DPYTHON_SUFFIX="-python${PYTHON_ABI}"
+			$(cmake-utils_use_build test TESTS)
+			$(cmake-utils_use_disable X QtGui)
+			$(cmake-utils_use_disable X QtDesigner)
+			$(cmake-utils_use_disable X QtTest)
+			$(cmake-utils_use_disable X QtUiTools)
+			$(cmake-utils_use_disable declarative QtDeclarative)
+			$(cmake-utils_use_disable help QtHelp)
+			$(cmake-utils_use_disable multimedia QtMultimedia)
+			$(cmake-utils_use_disable opengl QtOpenGL)
+			$(cmake-utils_use_disable phonon)
+			$(cmake-utils_use_disable script QtScript)
+			$(cmake-utils_use_disable scripttools QtScriptTools)
+			$(cmake-utils_use_disable sql QtSql)
+			$(cmake-utils_use_disable svg QtSvg)
+			$(cmake-utils_use_disable webkit QtWebKit)
+			$(cmake-utils_use_disable xmlpatterns QtXmlPatterns)
+		)
+		CMAKE_BUILD_DIR="${S}_${PYTHON_ABI}" cmake-utils_src_configure
+	}
+	python_execute_function configuration
+}
+
+src_compile() {
+	compilation() {
+		CMAKE_BUILD_DIR="${S}_${PYTHON_ABI}" cmake-utils_src_make
+	}
+	python_execute_function compilation
+}
+
+src_test() {
+	testing() {
+		CMAKE_BUILD_DIR="${S}_${PYTHON_ABI}" virtualmake
+	}
+	python_execute_function testing
+}
+
+src_install() {
+	installation() {
+		CMAKE_BUILD_DIR="${S}_${PYTHON_ABI}" cmake-utils_src_install
+		mv "${ED}"usr/$(get_libdir)/pkgconfig/${PN}{,-python${PYTHON_ABI}}.pc || die
+	}
+	python_execute_function installation
+}