version bump. adds support for H264 compression in videos. fixes crashers

Package-Manager: portage-2.1.6.1/cvs/Linux 2.6.27-gentoo-r7 x86_64

2 files changed, 103 insertions, 1 deletions

diff --git a/media-libs/swfdec/ChangeLog b/media-libs/swfdec/ChangeLog
index 1446891ce061..8a8133a8f0ef 100644
--- a/media-libs/swfdec/ChangeLog
+++ b/media-libs/swfdec/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/swfdec
 # Copyright 2000-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/swfdec/ChangeLog,v 1.55 2008/11/13 19:27:50 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/swfdec/ChangeLog,v 1.56 2008/12/24 14:25:44 cardoe Exp $
+
+*swfdec-0.8.4 (24 Dec 2008)
+
+  24 Dec 2008; Doug Goldstein <cardoe@gentoo.org> +swfdec-0.8.4.ebuild:
+  version bump. adds support for H264 compression in videos. fixes crashers
 
   13 Nov 2008; Brent Baude <ranger@gentoo.org> swfdec-0.6.8.ebuild:
   Marking swfdec-0.6.8 ppc64 stable for bug 236971
diff --git a/media-libs/swfdec/swfdec-0.8.4.ebuild b/media-libs/swfdec/swfdec-0.8.4.ebuild
new file mode 100644
index 000000000000..95cd81019e67
--- /dev/null
+++ b/media-libs/swfdec/swfdec-0.8.4.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/swfdec/swfdec-0.8.4.ebuild,v 1.1 2008/12/24 14:25:44 cardoe Exp $
+
+EAPI=1
+
+inherit eutils versionator
+
+MY_PV=$(get_version_component_range 1-2)
+DESCRIPTION="Macromedia Flash decoding library"
+HOMEPAGE="http://swfdec.freedesktop.org"
+SRC_URI="http://swfdec.freedesktop.org/download/${PN}/${MY_PV}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+
+IUSE="alsa doc ffmpeg gstreamer +gtk oss pulseaudio"
+
+RDEPEND=">=dev-libs/glib-2.16
+	>=dev-libs/liboil-0.3.1
+	>=x11-libs/pango-1.16.4
+	gtk? (
+		>=x11-libs/gtk+-2.8.0
+		net-libs/libsoup:2.4
+		)
+	>=x11-libs/cairo-1.6
+	gstreamer? (
+		>=media-libs/gstreamer-0.10.11
+		>=media-libs/gst-plugins-base-0.10.15
+		ffmpeg? ( media-plugins/gst-plugins-ffmpeg )
+		)
+	alsa? ( >=media-libs/alsa-lib-1.0.12 )
+	pulseaudio? ( media-sound/pulseaudio )"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( >=dev-util/gtk-doc-1.6 )"
+
+RESTRICT="test"
+
+pkg_setup() {
+	if use !gtk ; then
+		ewarn "swfdec will be built without swfdec-gtk convenience"
+		ewarn "library, which is needed by swfdec-mozilla and"
+		ewarn "swfdec-gnome. Please add 'gtk' to your USE flags"
+		ewarn "unless you really know what you are doing."
+	fi
+
+	if use !gstreamer && use ffmpeg; then
+		ewarn
+		ewarn "The 'ffmpeg' USE flag enables video support via gst-plugins-ffmpeg"
+		ewarn "as such it requires the 'gstreamer' USE flag to be enabled."
+	fi
+
+	if use alsa && use pulseaudio; then
+		ewarn
+		ewarn "Pulseaudio and ALSA selected. Selecting mature ALSA backend."
+	fi
+}
+
+src_compile() {
+	# Backend logic is from configure.ac:
+	# alsa > pulseaudio > oss
+	local audio="none"
+	use oss && audio="oss"
+	use pulseaudio && audio="pulse"
+	use alsa && audio="alsa"
+
+	# bug #216009
+	# avoid writing to /root/.gstreamer-0.10/registry.xml
+	export GST_REGISTRY="${T}"/registry.xml
+	# also avoid loading gconf plugins, which may write to /root/.gconfd
+	export GST_PLUGIN_SYSTEM_PATH="${T}"
+
+	econf \
+		$(use_enable doc gtk-doc) \
+		$(use_enable gstreamer) \
+		$(use_enable gtk) \
+		--disable-ffmpeg \
+		--disable-mad \
+		--with-audio=${audio} || die "configure failed"
+
+	# bug #216284 image tests are not ready yet
+	cat  >test/image/Makefile <<EOF
+all:
+check:
+install:
+EOF
+
+	emake || die "emake failed"
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "emake install failed"
+	dodoc AUTHORS ChangeLog README
+}