Add new snapshot to work with new x264 snapshot (bug 287850), add subversion as buildtime dep for snapshots (bug 287241).

Package-Manager: portage-2.2_rc44/cvs/Linux x86_64

4 files changed, 172 insertions, 5 deletions

diff --git a/media-video/avidemux/ChangeLog b/media-video/avidemux/ChangeLog
index 3537f5fb36f7..b0bbf7c8db73 100644
--- a/media-video/avidemux/ChangeLog
+++ b/media-video/avidemux/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/avidemux
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.156 2009/10/20 16:23:35 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/ChangeLog,v 1.157 2009/10/21 22:18:55 yngwin Exp $
+
+*avidemux-2.5.1_p5396 (21 Oct 2009)
+
+  21 Oct 2009; Ben de Groot <yngwin@gentoo.org> avidemux-2.5.1_p5359.ebuild,
+  +avidemux-2.5.1_p5396.ebuild:
+  Add new snapshot to work with new x264 snapshot (bug 287850), add
+  subversion as buildtime dep for snapshots (bug 287241).
 
   20 Oct 2009; Samuli Suominen <ssuominen@gentoo.org>
   avidemux-2.4.4-r2.ebuild:
diff --git a/media-video/avidemux/Manifest b/media-video/avidemux/Manifest
index af84c6f5d954..54c0716d669b 100644
--- a/media-video/avidemux/Manifest
+++ b/media-video/avidemux/Manifest
@@ -6,11 +6,13 @@ AUX avidemux-2.4.3-x264.patch 1484 RMD160 ed487bb8f6a65fca9180790156411d84ee18fe
 AUX avidemux-2.4.4-gcc-4.4.patch 3946 RMD160 1be6fb90f05befb0399ef38ccb6358d082f27b0a SHA1 63de9ce7999af1b9f94c01b14ccd049c2b27f32a SHA256 d8e2392b4eb4a0e5573fe5bac10a9ac57ae0f16207e613543d8e61d7527914af
 AUX lavcodec-mpegvideo_mmx-asm-fix.patch 2443 RMD160 3b1b315ef1e5083f95807ce5419196c832a66aad SHA1 0bd5ca05d373f7fd63cafb03d5514cfc86d8504c SHA256 c6cfcf06da8a254e542077a7ac728be220d41fc0ad3c4b7001ac63de5f36bc6c
 DIST avidemux-2.5-r5359.tar.bz2 11182791 RMD160 5b187080f487d13e844d8837b8b0674352fdbad0 SHA1 156f05d5aa6ea9f5ed5212f04f2c169513525b2a SHA256 ac721bd90da6192f18b01acf2af465f79d52446c12e9b06133dd967ae0609fe8
+DIST avidemux-2.5-r5396.tar.bz2 11184633 RMD160 7f89378815657b85e1a7abc02de2a21c8bb8687a SHA1 eebbad96a280a8cba4a1fb9c0d1444baa08f9af2 SHA256 4b051a8231d9a9abf5c9c3f3f7c0d3c4c8a0557df758a6901fdb9e9e58b68e08
 DIST avidemux-2.5.1-patches-1.tar.bz2 3700 RMD160 6150cef25c8411c76816f800bc1d688e2771bebe SHA1 bdc6aab3f19c1ef71f3e04c23435f22452651fd9 SHA256 bcd472ea7c5f96c8bf8f48c2c93d53804912e94c77120dc8739e2c0ab122d69c
 DIST avidemux_2.4.4.tar.gz 6894690 RMD160 8bb2705b3e2d5379d833ec4fa06a01b897c06e04 SHA1 c50a00caf13a8ea1053e5994edeb59354192e18e SHA256 45aafd6e54047edcfe9c985f4c9523c0efd71f7d21dad5e584aceb92c63e2956
 DIST avidemux_2.5.1.tar.gz 13020725 RMD160 fc12d01cf4b98ddcf635c20b32f8890cc70ab23a SHA1 50fe78548e0ebf0611d23aa4755f332056520392 SHA256 2f5546b8a95da23f5c43202d9c7b465dd7a0012d689d483ad7eb44bae8ca5c92
 EBUILD avidemux-2.4.4-r2.ebuild 3538 RMD160 e88f8a04653b628a1300b4d73473a320f2a79655 SHA1 55b9f7303d74ecfe14f1a5a2f654e2413f1214a9 SHA256 76527af36b493063cda3442d0ad2713847a02518e767969b6fdc94b381118849
 EBUILD avidemux-2.5.1-r2.ebuild 4955 RMD160 bf3971eec4b58d10c6d5241af9f8725d78c9f101 SHA1 66279aae61f9a66503f628c5358a1776e03e33e0 SHA256 4a1a5ddcef86f2e9e0d9141b8172ad31246a499415fb903ac07faf38c22ca374
-EBUILD avidemux-2.5.1_p5359.ebuild 4811 RMD160 8db5673c738e6ffaab55934d691f30d6fe66924b SHA1 9e6c4fed123626c6350554eeb97fc64d332611f6 SHA256 9a43b8ed6ef572deac7be60156a5a43a44d96a0e5c8687c1127414214c9d98b8
-MISC ChangeLog 27779 RMD160 3085c888a4acceea281493ba4c04513fe4d26618 SHA1 5281739b5c15cbfe1de0e48ecc165176a94cc622 SHA256 95ca23fd9be4a033356f953505b035c1403cffca04e7a2d23dc1168fdef4fea2
+EBUILD avidemux-2.5.1_p5359.ebuild 4831 RMD160 5d758328a1bcbd6162de23f6482450ee58972af0 SHA1 0d90aece6de1bff9063826568d5717d955843731 SHA256 65bedcc60ff3d20b4e7c04e341d5926a16fd58d3fad0dfbb11e5c00617941d7d
+EBUILD avidemux-2.5.1_p5396.ebuild 4832 RMD160 d1b28d72d6f6c9684026eee9d94451655cdf48df SHA1 cc1203e9efc3e480551979ccccb1a80605080edc SHA256 8576699b93e7a26059a368505d468f372c675ada32e2f694f21274e18c7fbce9
+MISC ChangeLog 28049 RMD160 9d9c21152e550ad16be91ee1f8d554e3559ce393 SHA1 43a0d41cd7b2f80fd5a449c803d1ce120d0f6dac SHA256 89621c88f6a25ce8395be9791768f5234810148207a3e507a05b39e337be910c
 MISC metadata.xml 465 RMD160 cbd50d211f2ad02fa9eb5da75509396f8464b6cc SHA1 e22f8fba25f6138d4a29c93079afbddf96832c33 SHA256 06d094aee75706e06b7f50e739616add134f188aef4a110d5912bdf2fd25e501
diff --git a/media-video/avidemux/avidemux-2.5.1_p5359.ebuild b/media-video/avidemux/avidemux-2.5.1_p5359.ebuild
index f77ca846cda3..564aa6a5ac91 100644
--- a/media-video/avidemux/avidemux-2.5.1_p5359.ebuild
+++ b/media-video/avidemux/avidemux-2.5.1_p5359.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.5.1_p5359.ebuild,v 1.1 2009/09/30 18:44:08 yngwin Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.5.1_p5359.ebuild,v 1.2 2009/10/21 22:18:56 yngwin Exp $
 
 EAPI="2"
 
@@ -36,7 +36,7 @@ RDEPEND="dev-libs/libxml2
 	truetype? ( media-libs/freetype:2
 		media-libs/fontconfig )
 	vorbis? ( media-libs/libvorbis )
-	x264? ( >=media-libs/x264-0.0.20090908 )
+	x264? ( ~media-libs/x264-0.0.20090908 )
 	xv? ( x11-libs/libXv )
 	xvid? ( media-libs/xvid )
 	gtk? ( x11-libs/gtk+:2 )
@@ -44,6 +44,7 @@ RDEPEND="dev-libs/libxml2
 DEPEND="${RDEPEND}
 	nls? ( sys-devel/gettext )
 	dev-util/pkgconfig
+	dev-util/subversion
 	>=dev-util/cmake-2.6.4"
 
 S=${WORKDIR}/${MY_P}
diff --git a/media-video/avidemux/avidemux-2.5.1_p5396.ebuild b/media-video/avidemux/avidemux-2.5.1_p5396.ebuild
new file mode 100644
index 000000000000..29e25bb2ece7
--- /dev/null
+++ b/media-video/avidemux/avidemux-2.5.1_p5396.ebuild
@@ -0,0 +1,157 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/avidemux/avidemux-2.5.1_p5396.ebuild,v 1.1 2009/10/21 22:18:56 yngwin Exp $
+
+EAPI="2"
+
+inherit cmake-utils
+
+MY_P=${PN}-2.5-r5396
+
+DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
+HOMEPAGE="http://fixounet.free.fr/avidemux"
+SRC_URI="mirror://gentoo/${MY_P}.tar.bz2
+	mirror://gentoo/${P%_*}-patches-1.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="2"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="+aac +aften +alsa amr +dts esd jack libsamplerate +mp3 nls oss
+	pulseaudio +sdl +truetype +vorbis +x264 +xv +xvid gtk +qt4"
+
+RDEPEND="dev-libs/libxml2
+	aac? ( media-libs/faac
+		media-libs/faad2 )
+	aften? ( media-libs/aften )
+	alsa? ( media-libs/alsa-lib )
+	amr? ( media-libs/opencore-amr )
+	dts? ( media-libs/libdca )
+	mp3? ( media-sound/lame )
+	esd? ( media-sound/esound )
+	jack? ( media-sound/jack-audio-connection-kit )
+	libsamplerate? ( media-libs/libsamplerate )
+	oss? ( media-libs/alsa-oss )
+	pulseaudio? ( media-sound/pulseaudio )
+	sdl? ( media-libs/libsdl )
+	truetype? ( media-libs/freetype:2
+		media-libs/fontconfig )
+	vorbis? ( media-libs/libvorbis )
+	x264? ( >=media-libs/x264-0.0.20090908 )
+	xv? ( x11-libs/libXv )
+	xvid? ( media-libs/xvid )
+	gtk? ( x11-libs/gtk+:2 )
+	qt4? ( >=x11-libs/qt-gui-4.5.1:4 )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	dev-util/pkgconfig
+	dev-util/subversion
+	>=dev-util/cmake-2.6.4"
+
+S=${WORKDIR}/${MY_P}
+
+AVIDEMUX_LANGS="bg ca cs de el es fr it ja pt_BR ru sr sr@latin tr zh_TW"
+for L in ${AVIDEMUX_LANGS}; do
+	IUSE="${IUSE} linguas_${L}"
+done
+
+PATCHES=( "${WORKDIR}/patches/${PV%_*}-i18n.patch"
+	"${WORKDIR}/patches/${PV%_*}-coreImage-parallel-build.patch" )
+
+src_prepare() {
+	base_src_prepare
+
+	local po_files=
+	local qt_ts_files=
+	local avidemux_ts_files=
+	for lingua in ${LINGUAS}; do
+		if has ${lingua} ${AVIDEMUX_LANGS}; then
+			if [[ -e ${S}/po/${lingua}.po ]]; then
+				po_files="${po_files} \${po_subdir}/${lingua}.po"
+			fi
+			if [[ -e ${S}/po/qt_${lingua}.ts ]]; then
+				qt_ts_files="${qt_ts_files} \${ts_subdir}/qt_${lingua}.ts"
+			fi
+			if [[ -e ${S}/po/${PN}_${lingua}.ts ]]; then
+				avidemux_ts_files="${avidemux_ts_files} \${ts_subdir}/${PN}_${lingua}.ts"
+			fi
+		fi
+	done
+
+	sed -i -e "s!FILE(GLOB po_files .*)!SET(po_files ${po_files})!" \
+		"${S}/cmake/Po.cmake" || die "sed failed"
+	sed -i -e "s!FILE(GLOB.*qt.*)!SET(ts_files ${qt_ts_files})!" \
+	    -e "s!FILE(GLOB.*avidemux.*)!SET(ts_files ${avidemux_ts_files})!" \
+		"${S}/cmake/Ts.cmake" || die "sed failed"
+}
+
+src_configure() {
+	mycmakeargs="${mycmakeargs}
+		-DAVIDEMUX_SOURCE_DIR='${S}'
+		-DAVIDEMUX_INSTALL_PREFIX='${S}_build'
+		-DAVIDEMUX_CORECONFIG_DIR='${S}_build/config'"
+
+	# CMakeLists.txt
+	use gtk || mycmakeargs="${mycmakeargs} -DGTK=0"
+	use qt4 || mycmakeargs="${mycmakeargs} -DQT4=0"
+
+	# cmake/admCheckMiscLibs.cmake
+	use nls || mycmakeargs="${mycmakeargs} -DGETTEXT=0"
+	use sdl || mycmakeargs="${mycmakeargs} -DSDL=0"
+	use xv || mycmakeargs="${mycmakeargs} -DXVIDEO=0"
+
+	# cmake/admCheckAudioDeviceLibs.cmake
+	use alsa || mycmakeargs="${mycmakeargs} -DALSA=0"
+	use esd || mycmakeargs="${mycmakeargs} -DESD=0"
+	use jack || mycmakeargs="${mycmakeargs} -DJACK=0"
+	use oss || mycmakeargs="${mycmakeargs} -DOSS=0"
+	use pulseaudio || mycmakeargs="${mycmakeargs} -DPULSEAUDIOSIMPLE=0"
+
+	# cmake/admCheckAudioEncoderLibs.cmake
+	use aften || mycmakeargs="${mycmakeargs} -DAFTEN=0"
+	use mp3 || mycmakeargs="${mycmakeargs} -DLAME=0"
+	use aac || mycmakeargs="${mycmakeargs} -DFAAC=0"
+	use vorbis || mycmakeargs="${mycmakeargs} -DVORBIS=0"
+
+	# plugins/ADM_audioDecoders
+	use aac || mycmakeargs="${mycmakeargs} -DFAAD=0"
+	use dts || mycmakeargs="${mycmakeargs} -DLIBDCA=0"
+
+	# opencore
+	use amr || mycmakeargs="${mycmakeargs} -DOPENCORE_AMRNB=0 -DOPENCORE_AMRWB=0"
+
+	# plugins/ADM_videoFilters
+	use truetype || mycmakeargs="${mycmakeargs} -DFREETYPE2=0 -DFONTCONFIG=0"
+
+	# plugins/ADM_videoEncoder
+	use xvid || mycmakeargs="${mycmakeargs} -DXVID=0"
+	use x264 || mycmakeargs="${mycmakeargs} -DX264=0"
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	# first build the application
+	cmake-utils_src_compile
+	# and then go on with plugins
+	emake -C "${CMAKE_BUILD_DIR}/plugins" || die "building plugins failed"
+}
+
+src_install() {
+	# install the application
+	cmake-utils_src_install
+	# install plugins
+	emake -C "${CMAKE_BUILD_DIR}/plugins" DESTDIR="${D}" install \
+		|| die "installing plugins failed"
+
+	dodoc AUTHORS || die "dodoc failed"
+	newicon ${PN}_icon.png ${PN}.png || die "installing icon failed"
+
+	if use qt4; then
+		sed -i "s/\(${PN}2_\)gtk/\1qt4/" ${PN}2.desktop || die "sed failed"
+		domenu ${PN}2.desktop || die "installing desktop file failed"
+	fi
+
+	if use gtk; then
+		domenu ${PN}2-gtk.desktop || die "installing desktop file failed"
+	fi
+}