Version bump.

Package-Manager: portage-2.2.18/cvs/Linux x86_64
Manifest-Sign-Key: 0xA792A613

1 files changed, 114 insertions, 0 deletions

diff --git a/net-misc/chrony/chrony-2.0.ebuild b/net-misc/chrony/chrony-2.0.ebuild
new file mode 100644
index 000000000000..d83e7c74a08d
--- /dev/null
+++ b/net-misc/chrony/chrony-2.0.ebuild
@@ -0,0 +1,114 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/chrony/chrony-2.0.ebuild,v 1.1 2015/05/04 05:31:22 jer Exp $
+
+EAPI=5
+inherit eutils systemd toolchain-funcs
+
+DESCRIPTION="NTP client and server programs"
+HOMEPAGE="http://chrony.tuxfamily.org/"
+SRC_URI="http://download.tuxfamily.org/${PN}/${P/_/-}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+
+KEYWORDS="~amd64 ~arm ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="caps +cmdmon ipv6 libedit +ntp +phc +pps readline +refclock +rtc selinux +adns"
+REQUIRED_USE="
+	?? ( libedit readline )
+"
+
+CDEPEND="
+	caps? ( sys-libs/libcap )
+	libedit? ( dev-libs/libedit )
+	readline? ( >=sys-libs/readline-4.1-r4:= )
+"
+DEPEND="
+	${CDEPEND}
+	sys-apps/texinfo
+"
+RDEPEND="
+	${CDEPEND}
+	selinux? ( sec-policy/selinux-chronyd )
+"
+
+RESTRICT=test
+
+S="${WORKDIR}/${P/_/-}"
+
+src_prepare() {
+	sed -i \
+		-e 's:/etc/chrony\.:/etc/chrony/chrony.:g' \
+		-e 's:/var/run:/run:g' \
+		conf.c chrony.texi.in chrony.txt examples/* FAQ || die
+}
+
+src_configure() {
+	tc-export CC
+
+	local CHRONY_EDITLINE
+	# ./configure legend:
+	# --disable-readline : disable line editing entirely
+	# --without-readline : do not use sys-libs/readline (enabled by default)
+	# --without-editline : do not use dev-libs/libedit (enabled by default)
+	if ! use readline && ! use libedit; then
+		CHRONY_EDITLINE='--disable-readline'
+	else
+		CHRONY_EDITLINE+=" $(usex readline '' --without-readline)"
+		CHRONY_EDITLINE+=" $(usex libedit '' --without-editline)"
+	fi
+
+	# not an autotools generated script
+	local CHRONY_CONFIGURE="
+	./configure \
+		$(usex caps '' --disable-linuxcaps) \
+		$(usex cmdmon '' --disable-cmdmon) \
+		$(usex ipv6 '' --disable-ipv6) \
+		$(usex ntp '' --disable-ntp) \
+		$(usex phc '' --disable-phc) \
+		$(usex pps '' --disable-pps) \
+		$(usex rtc '' --disable-rtc) \
+		$(usex refclock '' --disable-refclock) \
+		$(usex adns '' --disable-asyncdns) \
+		${CHRONY_EDITLINE} \
+		${EXTRA_ECONF} \
+		--docdir=/usr/share/doc/${PF} \
+		--infodir=/usr/share/info \
+		--mandir=/usr/share/man \
+		--prefix=/usr \
+		--sysconfdir=/etc/chrony \
+		--disable-sechash \
+		--without-nss \
+		--without-tomcrypt
+	"
+
+	# print the ./configure call to aid in future debugging
+	einfo ${CHRONY_CONFIGURE}
+	sh ${CHRONY_CONFIGURE} || die
+}
+
+src_compile() {
+	emake all docs
+}
+
+src_install() {
+	default
+	rm "${D}"/usr/share/doc/${PF}/COPYING || die
+	doinfo chrony.info*
+
+	newinitd "${FILESDIR}"/chronyd.init chronyd
+	newconfd "${FILESDIR}"/chronyd.conf chronyd
+
+	insinto /etc/${PN}
+	newins examples/chrony.conf.example3 chrony.conf
+	newins examples/chrony.keys.example chrony.keys
+
+	dodoc examples/*.example*
+
+	keepdir /var/{lib,log}/chrony
+
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}"/chrony.logrotate chrony
+
+	systemd_newunit "${FILESDIR}"/chronyd.service-r2 chronyd.service
+	systemd_enable_ntpunit 50-chrony chronyd.service
+}