Version bump.

Package-Manager: portage-2.2.0_alpha81/cvs/Linux x86_64

4 files changed, 178 insertions, 2 deletions

diff --git a/x11-misc/xlockmore/ChangeLog b/x11-misc/xlockmore/ChangeLog
index 1d491aaf32da..84742b67bfb6 100644
--- a/x11-misc/xlockmore/ChangeLog
+++ b/x11-misc/xlockmore/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/xlockmore
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v 1.96 2011/12/16 05:22:09 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/ChangeLog,v 1.97 2011/12/23 02:42:08 radhermit Exp $
+
+*xlockmore-5.37 (23 Dec 2011)
+
+  23 Dec 2011; Tim Harder <radhermit@gentoo.org> +xlockmore-5.37.ebuild:
+  Version bump.
 
 *xlockmore-5.36 (16 Dec 2011)
 
diff --git a/x11-misc/xlockmore/xlockmore-5.37.ebuild b/x11-misc/xlockmore/xlockmore-5.37.ebuild
new file mode 100644
index 000000000000..788f42cfea92
--- /dev/null
+++ b/x11-misc/xlockmore/xlockmore-5.37.ebuild
@@ -0,0 +1,95 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xlockmore/xlockmore-5.37.ebuild,v 1.1 2011/12/23 02:42:08 radhermit Exp $
+
+EAPI=4
+inherit autotools eutils flag-o-matic pam
+
+DESCRIPTION="Just another screensaver application for X"
+HOMEPAGE="http://www.tux.org/~bagleyd/xlockmore.html"
+SRC_URI="http://ftp.tux.org/pub/tux/bagleyd/${PN}/${P}/${P}.tar.bz2"
+
+LICENSE="BSD GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="crypt debug esd gtk imagemagick motif nas opengl pam truetype xinerama xlockrc"
+
+RDEPEND="x11-libs/libX11
+	x11-libs/libXext
+	x11-libs/libXmu
+	x11-libs/libXpm
+	x11-libs/libXt
+	esd? ( media-sound/esound )
+	gtk? ( x11-libs/gtk+:2 )
+	imagemagick? ( media-gfx/imagemagick )
+	motif? ( >=x11-libs/openmotif-2.3:0 )
+	nas? ( media-libs/nas )
+	opengl? (
+		media-libs/mesa
+		truetype? ( >=media-libs/ftgl-2.1.3_rc5 )
+		)
+	pam? ( virtual/pam )
+	truetype? ( media-libs/freetype:2 )
+	xinerama? ( x11-libs/libXinerama )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	x11-proto/xineramaproto"
+
+MAKEOPTS="${MAKEOPTS} -j1"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-5.31-configure.in.patch \
+		"${FILESDIR}"/${PN}-5.31-ldflags.patch
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=""
+
+	if use opengl && use truetype; then
+			myconf="${myconf} --with-ftgl"
+			append-flags -DFTGL213
+		else
+			myconf="${myconf} --without-ftgl"
+	fi
+
+	econf \
+		--enable-vtlock \
+		--enable-syslog \
+		$(use_enable xlockrc) \
+		$(use_enable pam) \
+		--disable-use-mb \
+		--enable-appdefaultdir=/usr/share/X11/app-defaults \
+		$(use_with motif) \
+		$(use_with imagemagick magick) \
+		$(use_with debug editres) \
+		$(use_with truetype ttf) \
+		$(use_with truetype freetype) \
+		$(use_with opengl) \
+		$(use_with opengl mesa) \
+		$(use_with xinerama) \
+		$(use_with esd esound) \
+		$(use_with nas) \
+		$(use_with crypt) \
+		$(use_with gtk gtk2) \
+		--without-gtk \
+		${myconf}
+}
+
+src_install() {
+	einstall xapploaddir="${D}/usr/share/X11/app-defaults" \
+		mandir="${D}/usr/share/man/man1" INSTPGMFLAGS=""
+
+	pamd_mimic_system xlock auth
+
+	if use pam; then
+		fperms 755 /usr/bin/xlock
+	else
+		fperms 4755 /usr/bin/xlock
+	fi
+
+	dohtml docs/xlock.html
+	dodoc README docs/{3d.howto,cell_automata,HACKERS.GUIDE,Purify,Revisions,TODO}
+}
diff --git a/x11-misc/xnee/ChangeLog b/x11-misc/xnee/ChangeLog
index 70b6c8e11560..03d116972847 100644
--- a/x11-misc/xnee/ChangeLog
+++ b/x11-misc/xnee/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-misc/xnee
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/xnee/ChangeLog,v 1.21 2011/12/02 22:20:09 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xnee/ChangeLog,v 1.22 2011/12/23 02:46:25 radhermit Exp $
+
+*xnee-3.11 (23 Dec 2011)
+
+  23 Dec 2011; Tim Harder <radhermit@gentoo.org> +xnee-3.11.ebuild:
+  Version bump.
 
   02 Dec 2011; Samuli Suominen <ssuominen@gentoo.org> xnee-3.10.ebuild:
   Remove support for building applet for gnome-panel-2.x (because it doesn't
diff --git a/x11-misc/xnee/xnee-3.11.ebuild b/x11-misc/xnee/xnee-3.11.ebuild
new file mode 100644
index 000000000000..3fccfd735d10
--- /dev/null
+++ b/x11-misc/xnee/xnee-3.11.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/xnee/xnee-3.11.ebuild,v 1.1 2011/12/23 02:46:25 radhermit Exp $
+
+EAPI=4
+
+inherit eutils
+
+DESCRIPTION="Program suite to record, replay and distribute user actions."
+HOMEPAGE="http://www.sandklef.com/xnee/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gnome static-libs xosd"
+
+RDEPEND="
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXi
+	x11-libs/libXtst
+	x11-libs/libxcb
+	gnome? (
+		x11-libs/gtk+:2
+		>=gnome-base/libgnomeui-2
+		>=gnome-base/gconf-2
+	)
+"
+DEPEND="${RDEPEND}
+	x11-proto/inputproto
+	dev-util/pkgconfig
+	sys-devel/gettext
+	gnome? ( || ( media-gfx/imagemagick[jpeg,png]
+		media-gfx/graphicsmagick[imagemagick,jpeg,png] ) )"
+
+# This needs RECORD extension from X.org server which isn't necessarily
+# enabled. Xlib: extension "RECORD" missing on display ":0.0".
+RESTRICT="test"
+
+src_configure() {
+	local myconf
+
+	if use xosd; then
+		myconf="--enable-xosd --enable-verbose --enable-buffer_verbose"
+	else
+		myconf="--disable-xosd --disable-verbose --disable-buffer_verbose"
+	fi
+
+	econf \
+		$(use_enable gnome gui) \
+		--disable-gnome-applet \
+		$(use_enable static-libs static) \
+		--enable-cli \
+		--enable-lib \
+		--disable-static-programs \
+		${myconf}
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	default
+	dodoc AUTHORS BUGS ChangeLog FAQ NEWS README TODO
+	use gnome && make_desktop_entry gnee Gnee ${PN} "Utility;GTK"
+	use static-libs || rm -f "${ED}"usr/lib*/lib*.la
+}