1 files changed, 57 insertions, 0 deletions
diff --git a/app-admin/ansible/ansible-1.5.0.ebuild b/app-admin/ansible/ansible-1.5.0.ebuild
new file mode 100644
index 000000000000..93091fb62c0d
--- /dev/null
+++ b/app-admin/ansible/ansible-1.5.0.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/ansible/ansible-1.5.0.ebuild,v 1.1 2014/03/03 12:21:30 pinkbyte Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1 readme.gentoo
+
+DESCRIPTION="Radically simple deployment, model-driven configuration management, and command execution framework"
+HOMEPAGE="http://ansible.com/"
+SRC_URI="https://github.com/ansible/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="test"
+
+DEPEND="test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)"
+RDEPEND="
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/keyczar[${PYTHON_USEDEP}]
+	dev-python/pyyaml[${PYTHON_USEDEP}]
+	dev-python/paramiko[${PYTHON_USEDEP}]
+	net-misc/sshpass
+	virtual/ssh
+"
+
+DOC_CONTENTS="You can define parameters through shell variables OR use config files
+Examples of config files installed in /usr/share/doc/${PF}/examples\n\n
+You have to create ansible hosts file!\n
+More info on http://docs.ansible.com/intro_getting_started.html"
+
+python_test() {
+	make tests || die "tests failed"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	doman docs/man/man1/*.1
+	dodoc -r examples
+	docompress -x /usr/share/doc/${PF}/examples
+	# Hint: do not install example config files into /etc
+	# let this choice to user
+
+	newenvd "${FILESDIR}"/${PN}.env 95ansible
+}
+
+src_install() {
+	distutils-r1_src_install
+	readme.gentoo_create_doc
+}