1 files changed, 57 insertions, 0 deletions
diff --git a/app-editors/retext/retext-4.0.1-r2.ebuild b/app-editors/retext/retext-4.0.1-r2.ebuild
new file mode 100644
index 000000000000..dde6631abf6f
--- /dev/null
+++ b/app-editors/retext/retext-4.0.1-r2.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/retext/retext-4.0.1-r2.ebuild,v 1.1 2013/09/04 12:42:49 tomwij Exp $
+
+EAPI="5"
+
+PYTHON_COMPAT=( python2_7 python3_2 )
+PLOCALES="ca cs cy da de es et eu fr it ja pl pt pt_BR ru sk uk zh_CN zh_TW"
+
+inherit distutils-r1 l10n
+
+MY_PN="ReText"
+MY_P="${MY_PN}-${PV/_/~}"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-2
+	EGIT_REPO_URI="git://git.code.sf.net/p/retext/git"
+	KEYWORDS=""
+else
+	SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="A Qt-based text editor for Markdown and reStructuredText"
+HOMEPAGE="http://sourceforge.net/p/retext/home/ReText/"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="+spell"
+
+RDEPEND+="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	dev-python/markdown[${PYTHON_USEDEP}]
+	dev-python/markups[${PYTHON_USEDEP}]
+	dev-python/PyQt4[webkit,${PYTHON_USEDEP}]
+	spell? ( dev-python/pyenchant )
+"
+
+S="${WORKDIR}"/${MY_P}
+
+src_install() {
+	distutils-r1_src_install
+
+	newicon {icons/,}${PN}.png
+	newicon {icons/,}${PN}.svg
+
+	l10n_for_each_disabled_locale_do remove_locale
+
+	make_desktop_entry ${PN} "${MY_PN} Editor" ${PN} "Development;Utility;TextEditor"
+
+	dosym /usr/bin/${PN}{.py,}
+}
+
+remove_locale() {
+	find "${D}" -name "retext_${1}.qm" -delete || die "Failed to remove locale ${1}."
+}