1 files changed, 56 insertions, 0 deletions
diff --git a/dev-cpp/libgnomecanvasmm/libgnomecanvasmm-2.26.0-r1.ebuild b/dev-cpp/libgnomecanvasmm/libgnomecanvasmm-2.26.0-r1.ebuild
new file mode 100644
index 000000000000..0f9c8c27d008
--- /dev/null
+++ b/dev-cpp/libgnomecanvasmm/libgnomecanvasmm-2.26.0-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-cpp/libgnomecanvasmm/libgnomecanvasmm-2.26.0-r1.ebuild,v 1.1 2014/07/08 11:58:23 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME_TARBALL_SUFFIX="bz2"
+
+inherit gnome2
+
+DESCRIPTION="C++ bindings for libgnomecanvas"
+HOMEPAGE="http://www.gtkmm.org"
+
+LICENSE="LGPL-2.1"
+SLOT="2.6"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc examples"
+
+RDEPEND="
+	>=gnome-base/libgnomecanvas-2.6
+	>=dev-cpp/gtkmm-2.4:2.4
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_prepare() {
+	if ! use examples; then
+		# don't waste time building the examples
+		sed -i 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' Makefile.in || \
+			die "sed Makefile.in failed"
+	fi
+	gnome2_src_prepare
+}
+
+src_compile() {
+	gnome2_src_compile
+
+	if use doc; then
+		cd "${S}/docs/reference"
+		emake all || die "failed to build API docs"
+	fi
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use doc ; then
+		dohtml -r docs/reference/html/*
+	fi
+
+	if use examples; then
+		cp -R examples "${D}/usr/share/doc/${PF}"
+	fi
+}