1 files changed, 60 insertions, 0 deletions
diff --git a/dev-ruby/httparty/httparty-0.5.1.ebuild b/dev-ruby/httparty/httparty-0.5.1.ebuild
new file mode 100644
index 000000000000..739491dfe725
--- /dev/null
+++ b/dev-ruby/httparty/httparty-0.5.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/httparty/httparty-0.5.1.ebuild,v 1.1 2010/01/31 11:33:35 flameeyes Exp $
+
+EAPI=2
+
+# ruby19 → testsuite fails (might be crack's bug)
+# jruby → testsuite fails (seems like a testuite bug)
+USE_RUBY="ruby18"
+
+# We have a custom test function, but don't null this out so that the
+# deps are still added
+RUBY_FAKEGEM_TASK_TEST="none"
+
+RUBY_FAKEGEM_DOCDIR="rdoc"
+RUBY_FAKEGEM_EXTRADOC="README.rdoc History"
+
+inherit ruby-fakegem
+
+DESCRIPTION="Makes http fun! Also, makes consuming restful web services dead easy."
+HOMEPAGE="http://httparty.rubyforge.org/"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE=""
+
+# Code should most likely be patched, but for now…
+ruby_add_rdepend '~dev-ruby/crack-0.1.5'
+
+ruby_add_bdepend 'dev-ruby/rspec dev-ruby/fakeweb'
+
+USE_RUBY=ruby18 \
+	ruby_add_bdepend 'ruby_targets_ruby18 test' 'dev-util/cucumber dev-ruby/activesupport:2.3'
+
+all_ruby_prepare() {
+	# as often, Rakefile depends on Jeweler's presence
+	sed -i \
+		-e '/check_dependencies/s:^:#:' \
+		Rakefile || die
+}
+
+each_ruby_test() {
+	case ${RUBY} in
+		*ruby18)
+			# Cucumber-based tests only work on Ruby 1.8, as of today, so we only call them
+			${RUBY} -S rake spec features || die "cucumber tests failed"
+			;;
+		*)
+			${RUBY} -S rake spec || die "cucumber tests failed"
+			;;
+	esac
+}
+
+all_ruby_install() {
+	all_fakegem_install
+
+	docinto examples
+	dodoc examples/* || die
+}