app-emulation/spice/spice-0.10.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54

# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/spice/spice-0.10.0.ebuild,v 1.4 2012/05/03 18:49:07 jdhore Exp $

EAPI=4

DESCRIPTION="SPICE server and client."
HOMEPAGE="http://spice-space.org/"
SRC_URI="http://spice-space.org/download/releases/${P}.tar.bz2"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="amd64 ~x86"
IUSE="+client +gui sasl static static-libs"

RDEPEND=">=app-emulation/spice-protocol-0.10.0
	>=x11-libs/pixman-0.17.7
	media-libs/alsa-lib
	media-libs/celt:0.5.1
	dev-libs/openssl
	>=x11-libs/libXrandr-1.2
	x11-libs/libX11
	x11-libs/libXext
	x11-libs/libXrender
	x11-libs/libXfixes
	virtual/jpeg
	sys-libs/zlib
	client? ( gui? ( =dev-games/cegui-0.6* ) )
	sasl? ( dev-libs/cyrus-sasl )"
DEPEND="virtual/pkgconfig
	${RDEPEND}"

# maintainer notes:
# * opengl support is currently broken
# * add slirp for tunnel-support
# * add libcacard for smartcard support

src_configure() {
	local gui="$(use_enable gui)"
	use client || gui="--disable-gui"
	econf \
		$(use_enable static-libs static) \
		--disable-tunnel \
		${gui} \
		--disable-smartcard \
		$(use_enable client) \
		$(use_enable static static-linkage) \
		$(use_with sasl)
}

src_install() {
	default
	use static-libs || rm "${D}"/usr/lib*/*.la
}