dev-java/commons-configuration/commons-configuration-1.4.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65

# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/commons-configuration/commons-configuration-1.4.ebuild,v 1.3 2008/04/13 08:16:50 dertobi123 Exp $

JAVA_PKG_IUSE="doc source"

inherit eutils java-pkg-2 java-ant-2

DESCRIPTION="Java library for reading configuration data from a variety of sources."
HOMEPAGE="http://jakarta.apache.org/commons/configuration/"
SRC_URI="mirror://apache/jakarta/commons/configuration/source/${P}-src.tar.gz"

COMMON_DEPENDS="
	>=dev-java/commons-beanutils-1.7.0
	>=dev-java/commons-codec-1.3
	>=dev-java/commons-collections-3.1
	>=dev-java/commons-digester-1.6
	>=dev-java/commons-jxpath-1.2
	>=dev-java/commons-lang-2.3
	>=dev-java/commons-logging-1.0.4
	>=dev-java/commons-httpclient-3.0
	=dev-java/servletapi-2.4*"

DEPEND=">=virtual/jdk-1.4
	${COMMON_DEPENDS}"
RDEPEND=">=virtual/jre-1.4
	${COMMON_DEPENDS}"
LICENSE="Apache-2.0"
SLOT="0"

KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"

S="${WORKDIR}/${P}-src"

src_unpack() {
	unpack ${A}
	cd "${S}"

	# Tweak build classpath and don't automatically run tests
	epatch "${FILESDIR}/${P}-gentoo.patch"

	java-ant_rewrite-classpath
}

EANT_GENTOO_CLASSPATH="
	commons-beanutils-1.7
	commons-codec
	commons-collections
	commons-digester
	commons-jxpath
	commons-lang-2.1
	commons-logging
	commons-httpclient-3
	servletapi-2.4"

# Would need mockobjects with j2ee support which we don't have
# Check overlay for ebuild with test support
RESTRICT="test"

src_install() {
	java-pkg_newjar target/${P}.jar ${PN}.jar
	dodoc RELEASE-NOTES.txt || die
	use doc && java-pkg_dojavadoc dist/docs/api
	use source && java-pkg_dosrc src/java/*
}