dev-java/prefuse/prefuse-20071021_beta.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/prefuse/prefuse-20071021_beta.ebuild,v 1.5 2014/11/25 08:41:16 ago Exp $

EAPI=5

JAVA_PKG_IUSE="doc examples source"

inherit java-pkg-2 java-ant-2

MY_PV=${PV/_beta/}
MY_P=${PN}-beta-${MY_PV}
DESCRIPTION="UI toolkit for building highly interactive visualizations of structured and unstructured data"
SRC_URI="mirror://sourceforge/prefuse/${MY_P}.zip"
HOMEPAGE="http://prefuse.org"
LICENSE="BSD"
SLOT="2006"
KEYWORDS="amd64 ~ppc x86 ~x86-fbsd"

COMMON_DEP="dev-java/lucene:1"

DEPEND=">=virtual/jdk-1.4
	${COMMON_DEP}
	>=app-arch/unzip-5.50-r1"
RDEPEND=">=virtual/jre-1.4
	${COMMON_DEP}"

S=${WORKDIR}/${PN}-beta

java_prepare() {
	find lib/ -name "*.jar" | xargs rm -v
}

src_compile() {
	java-pkg_filter-compiler jikes
	local targets="prefuse"
	use examples && targets="${targets} demos"
	eant $(use_doc api) ${targets} \
		-Dlucene.lib=$(java-pkg_getjars lucene-1)
}

src_install() {
	java-pkg_dojar build/${PN}.jar

	dodoc readme.txt || die
	use doc && java-pkg_dojavadoc doc/api
	use source && java-pkg_dosrc src/*
	use examples && java-pkg_doexamples demos/*
}