blob: f6a23c19f4e15be65bd33026c793ccb8aed16c0b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/dbus-glib/dbus-glib-0.98.ebuild,v 1.11 2012/05/06 00:29:49 aballier Exp $
EAPI=4
inherit bash-completion-r1 eutils
DESCRIPTION="D-Bus bindings for glib"
HOMEPAGE="http://dbus.freedesktop.org/"
SRC_URI="http://dbus.freedesktop.org/releases/${PN}/${P}.tar.gz"
LICENSE="|| ( GPL-2 AFL-2.1 )"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x86-solaris"
IUSE="debug doc static-libs test"
RDEPEND=">=sys-apps/dbus-1.4.16
>=dev-libs/glib-2.26
>=dev-libs/expat-2"
DEPEND="${RDEPEND}
virtual/pkgconfig
doc? ( dev-util/gtk-doc )"
# out of sources build directory
BD=${WORKDIR}/${P}-build
# out of sources build dir for make check
TBD=${WORKDIR}/${P}-tests-build
src_prepare() {
epatch "${FILESDIR}"/${P}-glib-2.31.patch
}
src_configure() {
local myconf
myconf="--localstatedir=${EPREFIX}/var
--enable-bash-completion
$(use_enable debug verbose-mode)
$(use_enable debug asserts)
$(use_enable static-libs static)
$(use_enable doc gtk-doc)
--with-html-dir=${EPREFIX}/usr/share/doc/${PF}/html"
mkdir "${BD}"
cd "${BD}"
einfo "Running configure in ${BD}"
ECONF_SOURCE="${S}" econf ${myconf}
if use test; then
mkdir "${TBD}"
cd "${TBD}"
einfo "Running configure in ${TBD}"
ECONF_SOURCE="${S}" econf \
${myconf} \
$(use_enable test checks) \
$(use_enable test tests) \
$(use_enable test asserts) \
$(use_with test test-socket-dir "${T}"/dbus-test-socket)
fi
}
src_compile() {
cd "${BD}"
einfo "Running make in ${BD}"
emake
if use test; then
cd "${TBD}"
einfo "Running make in ${TBD}"
emake
fi
}
src_test() {
cd "${TBD}"
emake check
}
src_install() {
# NEWS file is obsolete
dodoc AUTHORS ChangeLog HACKING README
cd "${BD}"
emake DESTDIR="${D}" install
# FIXME: We need --with-bash-completion-dir
newbashcomp "${ED}"/etc/bash_completion.d/dbus-bash-completion.sh dbus
rm -rf "${ED}"/etc/bash_completion.d || die
find "${ED}" -name '*.la' -exec rm -f {} +
}
|
GitWeb