dev-libs/xqilla/xqilla-2.3.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72

# Copyright 1999-2014 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-libs/xqilla/xqilla-2.3.0.ebuild,v 1.2 2014/08/10 20:40:44 slyfox Exp $

EAPI="4"

inherit autotools base

MY_P="XQilla-${PV}"

DESCRIPTION="An XQuery and XPath 2 library and command line utility written in C++"
HOMEPAGE="http://xqilla.sourceforge.net/HomePage"
SRC_URI="mirror://sourceforge/${PN}/${MY_P}.tar.gz"
LICENSE="Apache-2.0 BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug doc examples faxpp htmltidy static-libs"

# XQilla bundles two libraries:
# - mapm, heavily patched
# - yajl, moderately patched
# There's currently no way to unbundle those

RDEPEND=">=dev-libs/xerces-c-3.1.1
	faxpp? ( dev-libs/faxpp )
	htmltidy? ( app-text/htmltidy )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )"

PATCHES=(
	"${FILESDIR}/2.2.4-respect-ldflags-no-rpath.patch"
)

S="${WORKDIR}/${MY_P}"

src_prepare() {
	base_src_prepare
	eautoreconf
}

src_configure() {
	econf \
		--with-xerces=/usr \
		$(use_enable debug) \
		$(use_with htmltidy tidy /usr) \
		$(use_with faxpp faxpp /usr) \
		$(use_enable static-libs static)
}

src_compile() {
	default

	if use doc; then
		emake docs || die "emake docs failed"
		emake devdocs || die "emake devdocs failed"
	fi
}

src_install () {
	default

	use static-libs || rm -rf "${D}"/usr/lib*/*.la

	if use doc; then
		cd docs
		dohtml -r dev-api dom3-api simple-api
	fi
	if use examples ; then
		insinto /usr/share/doc/${PF}/examples
		doins -r "${S}"/src/samples/*
	fi
}