blob: 9e5f4cabf7c3b38638b755e3a45c98ce91af0d6e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
# Copyright 1999-2005 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/dovecot/dovecot-1.0_alpha5.ebuild,v 1.2 2006/01/01 01:28:30 swegener Exp $
inherit eutils
DESCRIPTION="An IMAP and POP3 server written with security primarily in mind"
HOMEPAGE="http://dovecot.org/"
MY_P="${P/_/.}"
S="${WORKDIR}/${MY_P}"
SRC_URI="http://dovecot.org/releases/${MY_P}.tar.gz"
SLOT="0"
LICENSE="LGPL-2.1"
KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
IUSE="debug ipv6 kerberos ldap mbox mysql pop3d pam postgres ssl vpopmail"
DEPEND=">=sys-libs/db-3.2
>=sys-apps/sed-4
kerberos? ( virtual/krb5 )
ldap? ( net-nds/openldap )
pam? ( virtual/pam )
ssl? ( dev-libs/openssl )
postgres? ( dev-db/postgresql )
mysql? ( dev-db/mysql )
vpopmail? ( net-mail/vpopmail )"
RDEPEND="${DEPEND}
>=net-mail/mailbase-0.00-r8"
pkg_setup() {
# Add user and group for login process (same as for fedora/redhat)
enewgroup dovecot 97
enewuser dovecot 97 -1 /dev/null dovecot
}
src_compile() {
local myconf
use ssl && myconf="${myconf} --with-ssl=openssl" \
|| myconf="${myconf} --without-ssl"
# Enable when linux-headers-2.6.13 hits portage for inotify
# or epoll gets more stable.
#
# # Enable Linux only features
# if [[ ${KERNEL} == "linux" ]] ; then
# # epoll is too unstable
# # myconf="${myconf} --with-ioloop=epoll"
# if has_version ">=sys-kernel/linux-headers-2.6.13" ; then
# myconf="${myconf} --with-notify=inotify"
# fi
# fi
econf --localstatedir=/var \
$(use_enable debug) \
$(use_enable ipv6) \
$(use_with kerberos gssapi) \
$(use_with ldap) \
$(use_with mysql) \
$(use_with pam) \
$(use_with pop3d) \
$(use_with postgres pgsql) \
$(use_with vpopmail) \
${myconf} || die "configure failed"
emake || die "make failed"
}
src_install () {
make DESTDIR="${D}" install || die "make install failed"
newinitd "${FILESDIR}"/dovecot.init dovecot
# Create the dovecot.conf file from the dovecot-example.conf file that
# the dovecot folks nicely left for us....
mv "${D}"/etc/dovecot-example.conf "${D}"/etc/dovecot.conf
# .maildir is the Gentoo default, but we need to support mbox to
local mailenv="maildir:%h/.maildir"
if use mbox ; then
mailenv="mbox:/var/spool/mail/%u:INDEX=/var/dovecot/%u"
keepdir /var/dovecot
sed -i -e 's|#mail_extra_groups =|mail_extra_groups = mail|' \
"${D}"/etc/dovecot.conf
fi
sed -i -e \
"s|#default_mail_env =|default_mail_env = ${mailenv}|" \
"${D}"/etc/dovecot.conf
# We're using pam files (imap and pop3) provided by mailbase
if use pam ; then
sed -i -e '/passdb pam/, /^[ \t]*}/ s|#args = dovecot|args = "\*"|' \
"${D}"/etc/dovecot.conf
fi
# Documentation
rm -rf "${D}"/usr/share/doc/dovecot
dodoc AUTHORS NEWS README TODO dovecot-example.conf
dodoc doc/*.txt doc/*.conf doc/*.cnf doc/mkcert.sh
# Create SSL certificates
if use ssl ; then
dodir /etc/ssl/certs
dodir /etc/ssl/private
# Let's not make a new certificate if we already have one
if ! [[ -e /etc/ssl/certs/dovecot.pem && \
-e /etc/ssl/private/dovecot.pem ]]; then
einfo "Generating X.509 certificate for SSL"
pushd doc >/dev/null && \
SSLDIR="${D}"/etc/ssl sh mkcert.sh && \
popd >/dev/null
fi
fi
dodir /var/run/dovecot
fowners root:0 /var/run/dovecot
fperms 0700 /var/run/dovecot
keepdir /var/run/dovecot/login
fowners root:dovecot /var/run/dovecot/login
fperms 0750 /var/run/dovecot/login
fperms 0600 /etc/dovecot.conf
}
pkg_postinst() {
einfo "The dovecot configuration has vastly changed since 0.99."
einfo "You are encouraged to start afresh with a new configuration file."
einfo "see http://wiki.dovecot.org/ for configuration examples."
}
|
GitWeb