media-sound/tidal-hifi-bin: add 5.15.0

Signed-off-by: Kostadin Shishmanov <kocelfc@tutanota.com>

2 files changed, 100 insertions, 0 deletions

diff --git a/media-sound/tidal-hifi-bin/Manifest b/media-sound/tidal-hifi-bin/Manifest
index 3d67e8be8..c40d1453b 100644
--- a/media-sound/tidal-hifi-bin/Manifest
+++ b/media-sound/tidal-hifi-bin/Manifest
@@ -1 +1,2 @@
 DIST tidal-hifi-bin-5.14.1.tar.gz 113454019 BLAKE2B ee5b1bd0554376fa1e0e753e44ee9d5e0b6b8cf3e7e1c445d0962ef284df384662725dd4da960868c3d9f360b7bae2e18fdb3c3c05e7692faf31b3e964200cef SHA512 c50788b874bc61822d5eeb63a3ba8d67b6fb086c305d85b4c003fdb2ea9ff0f16a9c547cfb5d76a71fe7f9022e2bdc8167cdf6127a6931614581935c9de1f498
+DIST tidal-hifi-bin-5.15.0.tar.gz 113447478 BLAKE2B 2f1b7ee95ca1b7faed391634c8849d90c2c7c7307e828e762023281f478aa52b468c96b1df3dafdef79ae5706e8069ba1e65f38863646563d3e7b47a15a30c84 SHA512 b76a4c9ffa26645665c815b96ceb5dde33d73bb6e0e6b2a524738dcbdf0a00f9c7fdd2e72debb91e54175392c902a2bc71606e6fcdb9d96d356edc2a3edbd2e2
diff --git a/media-sound/tidal-hifi-bin/tidal-hifi-bin-5.15.0.ebuild b/media-sound/tidal-hifi-bin/tidal-hifi-bin-5.15.0.ebuild
new file mode 100644
index 000000000..fa242c2f3
--- /dev/null
+++ b/media-sound/tidal-hifi-bin/tidal-hifi-bin-5.15.0.ebuild
@@ -0,0 +1,99 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN="${PN/-bin/}"
+
+CHROMIUM_LANGS="
+	af am ar bg bn ca cs da de el en-GB en-US es es-419 et fa fi fil fr gu he hi
+	hr hu id it ja kn ko lt lv ml mr ms nb nl pl pt-BR pt-PT ro ru sk sl sr sv
+	sw ta te th tr uk ur vi zh-CN zh-TW
+"
+
+inherit chromium-2 desktop linux-info unpacker xdg
+
+DESCRIPTION="Web version of Tidal running in electron with Hi-Fi support thanks to Widevine."
+HOMEPAGE="https://github.com/Mastermindzh/tidal-hifi"
+SRC_URI="https://github.com/Mastermindzh/tidal-hifi/releases/download/${PV}/tidal-hifi-${PV}.tar.gz -> ${P}.tar.gz"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/libgcrypt
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/fontconfig
+	media-libs/mesa[gbm(+)]
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/libdrm
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXScrnSaver
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+"
+
+DESTDIR="/opt/${PN}"
+
+QA_PREBUILT="*"
+
+CONFIG_CHECK="~USER_NS"
+
+src_configure() {
+	default
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_prepare() {
+	default
+	# cleanup languages
+	pushd "locales/" >/dev/null || die "location change for language cleanup failed"
+	chromium_remove_language_paks
+	popd >/dev/null || die "location reset for language cleanup failed"
+	rm -rf "${S}"/resources/app.asar.unpacked/node_modules/{abstract-socket,register-scheme}/build/node_gyp_bins || die
+}
+
+src_install() {
+	doicon -s 256 "${FILESDIR}/${MY_PN}.png"
+
+	make_desktop_entry "/usr/bin/tidal-hifi" "TIDAL Hi-Fi" ${MY_PN} "Network;AudioVideo;Audio;Video"
+
+	exeinto "${DESTDIR}"
+
+	doexe "${MY_PN}" chrome-sandbox libEGL.so libffmpeg.so libGLESv2.so libvk_swiftshader.so
+
+	insinto "${DESTDIR}"
+	doins chrome_100_percent.pak chrome_200_percent.pak icudtl.dat resources.pak snapshot_blob.bin v8_context_snapshot.bin
+	insopts -m0755
+	doins -r locales resources
+
+	# Chrome-sandbox requires the setuid bit to be specifically set.
+	# see https://github.com/electron/electron/issues/17972
+	fowners root "${DESTDIR}/chrome-sandbox"
+	fperms 4711 "${DESTDIR}/chrome-sandbox"
+
+	[[ -x chrome_crashpad_handler ]] && doins chrome_crashpad_handler
+
+	dosym -r "${DESTDIR}/${MY_PN}" "/usr/bin/${MY_PN}"
+}