net-irc/srain: add 1.4.0, drop 1.2.1

Signed-off-by: Anna (cybertailor) Vyalkova <cyber+gentoo@sysrq.in>

3 files changed, 55 insertions, 43 deletions

diff --git a/net-irc/srain/Manifest b/net-irc/srain/Manifest
index 6dd8ea916..056268e63 100644
--- a/net-irc/srain/Manifest
+++ b/net-irc/srain/Manifest
@@ -1,2 +1,2 @@
-DIST srain-1.2.1.tar.gz 954668 BLAKE2B 20beb88761a387a041659ea11f852655daab9fdcd4b1d2f2b080bfa4dd9c19a61c12ebba9a581a10355d9249a6063dcdfea486dccb625622e68b57a4445afae7 SHA512 594cb65827ba3f4cf99820640103bdd1d67577df31e1fcb27f98722e243bcbab68420aff0c3f26cc7d0c149a4a8c256fc386709b8ff86d6b617c170f00c076f3
 DIST srain-1.2.4.tar.gz 954684 BLAKE2B 9989715380f0fb702a8f43be77ee5cd6360f2e8ddb2d21e8f1e0741fe6aabe3869b42e9e1f36c642b8cbfb6e2419f14d4ccc682f7fd7b1dda0f3b1af5b69e59f SHA512 96d15f9d8bccc197b1bcda2c4707bdeea8e5cb33e3a8ad88ea5431b059c64e2ccb2e82897fcb1c02198420fed2c59148ff1c32f5f305cfffa88f096e41b42cb4
+DIST srain-1.4.0.tar.gz 1935950 BLAKE2B 7d3db119bcc07ccb427850530e551f643e202d3f2f276c8b347324f99474e57052368b8eed52e74ba6403a47b3bd4b7842ee007d9035bbba8e69beba8e3be9e6 SHA512 1708d1d1ec97c9f35a8702526a95bb60bf0ea50b742a76081508ef42a512e8c113ef1949c3b9f3db4585d8fb11cdb197f65fc7bc10480a533c69982c21185e55
diff --git a/net-irc/srain/srain-1.2.1.ebuild b/net-irc/srain/srain-1.2.1.ebuild
deleted file mode 100644
index 0f8830628..000000000
--- a/net-irc/srain/srain-1.2.1.ebuild
+++ /dev/null
@@ -1,42 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit meson xdg
-
-DESCRIPTION="Modern, beautiful IRC client written in GTK+ 3"
-HOMEPAGE="https://github.com/SrainApp/srain"
-SRC_URI="https://github.com/SrainApp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~arm ~arm64 ~x86"
-IUSE="debug doc"
-
-RDEPEND="
-	>=x11-libs/gtk+-3.22.0
-	x11-libs/libnotify
-"
-DEPEND="
-	${RDEPEND}
-	app-crypt/libsecret
-	dev-libs/libconfig
-	net-libs/libsoup
-"
-BDEPEND="dev-python/sphinx"
-
-src_prepare() {
-	sed -i "s/'doc', meson.project_name())/'doc', meson.project_name() + '-${PV}')/" \
-		meson.build || die
-
-	xdg_src_prepare
-}
-
-src_configure() {
-	local emesonargs=(
-		--buildtype $(usex debug 'debug' 'plain')
-		-Ddoc_builders="['man'$(usex doc ', "html"' '')]"
-	)
-	meson_src_configure
-}
diff --git a/net-irc/srain/srain-1.4.0.ebuild b/net-irc/srain/srain-1.4.0.ebuild
new file mode 100644
index 000000000..3a75b9281
--- /dev/null
+++ b/net-irc/srain/srain-1.4.0.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} pypy3 )
+inherit meson python-any-r1 xdg
+
+DESCRIPTION="Modern, beautiful IRC client written in GTK+ 3"
+HOMEPAGE="https://github.com/SrainApp/srain"
+SRC_URI="https://github.com/SrainApp/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="doc man"
+
+RDEPEND="
+	app-crypt/libsecret
+	dev-libs/glib:2
+	dev-libs/libconfig:=
+	dev-libs/openssl:=
+	net-libs/libsoup:2.4
+	x11-libs/gtk+:3
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? ( ${PYTHON_DEPS} )
+	man? ( ${PYTHON_DEPS} )
+"
+
+python_check_deps() {
+	if use doc || use man; then
+		has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" || return 1
+	fi
+}
+
+src_prepare() {
+	default
+
+	sed "s/\('doc'\), meson.project_name()/\1, '${PF}'/" \
+		-i meson.build || die
+}
+
+src_configure() {
+	local -a doc_builders=()
+	use doc && doc_builders+=( html )
+	use man && doc_builders+=( man )
+
+	local emesonargs=(
+		-Ddoc_builders="$(meson-format-array "${doc_builders[@]}")"
+	)
+	meson_src_configure
+}