sys-apps/duc: version bump (v1.4.5)

Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>

Closes: https://bugs.gentoo.org/706804
Closes: https://bugs.gentoo.org/729362
Signed-off-by: Ulrich Müller <ulm@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/sys-apps/duc/Manifest b/sys-apps/duc/Manifest
index 018d009adebb..b2e69cdd72e3 100644
--- a/sys-apps/duc/Manifest
+++ b/sys-apps/duc/Manifest
@@ -1 +1,2 @@
 DIST duc-1.4.3.tar.gz 363507 BLAKE2B 8d4364d48c247d7a83c8c5dd900b1c36ec78c68fa7d090e178a0e3209583e433c2e459d192f65ac350038c7e0d5a57df2c5c0d649cc9f554d7af74ad960c8db5 SHA512 5eb3e862e7003838e012dd1faab507a9b58607b77bd2af70a662005b6e4008ac44d1fb2e17b99da8e42ddfadb1cede2a468144ace7a72c12d0825fc7df4d18cd
+DIST duc-1.4.5.tar.gz 288381 BLAKE2B dc597618a9e00258abef23ffded94711e6b66a37dce3cb078fe44ef2e1b253b7b48a46f38a545eb05ce4b83f0357d93c2a594ef82da0b81e6963fed8136d8ea6 SHA512 b6d48222ed2821d3d1317102f867f71f9060a093ba11ba48d9f0d9dc743c5b361442cb605aec6e91dd6588ae4b51897b4ed5da96ba33019e8a501a262af12371
diff --git a/sys-apps/duc/duc-1.4.5.ebuild b/sys-apps/duc/duc-1.4.5.ebuild
new file mode 100644
index 000000000000..a0fde0e3916e
--- /dev/null
+++ b/sys-apps/duc/duc-1.4.5.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+if [[ "${PV}" == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/zevv/duc.git"
+else
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="https://github.com/zevv/${PN}/releases/download/${PV}/${P}.tar.gz"
+fi
+
+DESCRIPTION="Library and suite of tools for inspecting disk usage"
+HOMEPAGE="https://github.com/zevv/duc"
+
+LICENSE="LGPL-3"
+SLOT="0"
+IUSE="cairo gui leveldb ncurses sqlite +tokyocabinet X"
+
+REQUIRED_USE="
+	^^ ( tokyocabinet leveldb sqlite )
+	X? ( cairo gui )
+"
+
+DEPEND="
+	cairo? ( x11-libs/cairo x11-libs/pango )
+	gui? (
+		X? (
+			x11-libs/cairo[X]
+			x11-libs/libX11
+			x11-libs/pango[X]
+		)
+		!X? ( >=media-libs/glfw-3.0 )
+	)
+	leveldb? ( dev-libs/leveldb:= )
+	ncurses? ( sys-libs/ncurses:= )
+	sqlite? ( dev-db/sqlite:3 )
+	tokyocabinet? ( dev-db/tokyocabinet )
+"
+RDEPEND="${DEPEND}"
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4.1-tinfo.patch
+)
+
+src_unpack() {
+	if [[ "${PV}" == "9999" ]]; then
+		git-r3_src_unpack
+	else
+		unpack ${A}
+	fi
+}
+
+src_prepare() {
+	sed -i -e "/ldconfig/d" -e "/install-exec-hook/d" Makefile.am || die
+
+	default
+
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=( $(use_enable ncurses ui) )
+
+	if use tokyocabinet; then
+		myconf+=( --with-db-backend=tokyocabinet )
+	elif use leveldb; then
+		myconf+=( --with-db-backend=leveldb )
+	else
+		myconf+=( --with-db-backend=sqlite3 )
+	fi
+
+	# Necessary logic for cairo
+	if use gui && use X; then
+		# X backend GUI
+		myconf+=( --enable-x11 --disable-opengl --enable-cairo )
+	elif use gui; then
+		# OpenGL backend GUI
+		myconf+=( --disable-x11 --enable-opengl $(use_enable cairo) )
+	else
+		# No GUI
+		myconf+=( $(use_enable cairo) --disable-x11 --disable-opengl )
+	fi
+
+	econf ${myconf[@]}
+}