proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 54 insertions, 0 deletions

diff --git a/app-emulation/ski/ski-1.3.2-r1.ebuild b/app-emulation/ski/ski-1.3.2-r1.ebuild
new file mode 100644
index 000000000000..875a6ddf4361
--- /dev/null
+++ b/app-emulation/ski/ski-1.3.2-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+
+inherit autotools eutils
+
+DESCRIPTION="ia64 instruction set simulator"
+HOMEPAGE="http://ski.sourceforge.net/ http://www.gelato.unsw.edu.au/IA64wiki/SkiSimulator"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+gtk motif"
+
+RDEPEND="dev-libs/libltdl:0
+	|| ( dev-libs/elfutils dev-libs/libelf )
+	sys-libs/ncurses
+	gtk? (
+		gnome-base/libglade:2.0
+		gnome-base/libgnomeui
+		x11-libs/gtk+:2
+	)
+	motif? ( x11-libs/motif )"
+DEPEND="${RDEPEND}
+	sys-devel/bison
+	sys-devel/flex
+	dev-util/gperf"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-syscall-linux-includes.patch
+	"${FILESDIR}"/${P}-remove-hayes.patch
+	"${FILESDIR}"/${P}-no-local-ltdl.patch
+	"${FILESDIR}"/${P}-AC_C_BIGENDIAN.patch
+	"${FILESDIR}"/${P}-configure-withval.patch
+	"${FILESDIR}"/${P}-binutils.patch
+)
+
+src_prepare() {
+	epatch "${PATCHES[@]}"
+
+	rm -rf libltdl src/ltdl.[ch] macros/ltdl.m4
+
+	AT_M4DIR="macros" eautoreconf
+}
+
+src_configure() {
+	econf \
+		--without-included-ltdl \
+		$(use_with gtk) \
+		$(use_with motif x11)
+}