app-emulation/virt-manager: update EAPI on 3.2.0-r1, use optfeature

 - drop useless runtime-only dependency for net-misc/x11-ssh-askpass.

Closes: https://bugs.gentoo.org/768981
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 106 insertions, 13 deletions

diff --git a/app-emulation/virt-manager/virt-manager-3.2.0-r1.ebuild b/app-emulation/virt-manager/virt-manager-3.2.0-r1.ebuild
new file mode 100644
index 000000000000..1bf166e0e62b
--- /dev/null
+++ b/app-emulation/virt-manager/virt-manager-3.2.0-r1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+DISTUTILS_SINGLE_IMPL=1
+
+DISTUTILS_USE_SETUPTOOLS=no
+inherit gnome2 distutils-r1 optfeature
+
+DESCRIPTION="A graphical tool for administering virtual machines"
+HOMEPAGE="https://virt-manager.org https://github.com/virt-manager/virt-manager"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/virt-manager/virt-manager.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="http://virt-manager.org/download/sources/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gtk policykit sasl"
+
+RDEPEND="${PYTHON_DEPS}
+	app-cdr/cdrtools
+	>=app-emulation/libvirt-glib-1.0.0[introspection]
+	$(python_gen_cond_dep '
+		dev-libs/libxml2[python,${PYTHON_USEDEP}]
+		dev-python/argcomplete[${PYTHON_USEDEP}]
+		>=dev-python/libvirt-python-6.10.0[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+	')
+	>=sys-libs/libosinfo-0.2.10[introspection]
+	gtk? (
+		gnome-base/dconf
+		>=net-libs/gtk-vnc-0.3.8[gtk3(+),introspection]
+		net-misc/spice-gtk[usbredir,gtk3,introspection,sasl?]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/gtksourceview:4[introspection]
+		x11-libs/vte:2.91[introspection]
+		policykit? ( sys-auth/polkit[introspection] )
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-python/docutils
+	dev-util/intltool"
+
+DOCS=( README.md NEWS.md )
+
+# Doesn't seem to play nicely in a sandboxed environment.
+RESTRICT="test"
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+}
+
+python_configure() {
+	esetup.py configure --default-graphics=spice
+}
+
+python_install() {
+	esetup.py install
+}
+
+src_install() {
+	local mydistutilsargs=( --no-update-icon-cache --no-compile-schemas )
+	distutils-r1_src_install
+
+	python_fix_shebang "${ED}"/usr/share/virt-manager
+}
+
+pkg_preinst() {
+	if use gtk; then
+		gnome2_pkg_preinst
+
+		cd "${ED}" || die
+		export GNOME2_ECLASS_ICONS=$(find 'usr/share/virt-manager/icons' -maxdepth 1 -mindepth 1 -type d 2> /dev/null || die)
+	else
+		rm -r "${ED}/usr/share/virt-manager/ui/" || die
+		rm -r "${ED}/usr/share/virt-manager/icons/" || die
+		rm -r "${ED}/usr/share/icons/" || die
+		rm -r "${ED}/usr/share/applications/virt-manager.desktop" || die
+		rm -r "${ED}/usr/bin/virt-manager" || die
+	fi
+}
+
+pkg_postinst() {
+	use gtk && gnome2_pkg_postinst
+	optfeature "SSH_ASKPASS program implementation" lxqt-base/lxqt-openssh-askpass net-misc/ssh-askpass-fullscreen net-misc/x11-ssh-askpass
+}
diff --git a/app-emulation/virt-manager/virt-manager-9999.ebuild b/app-emulation/virt-manager/virt-manager-9999.ebuild
index 40577b554f57..2b7f150c0d93 100644
--- a/app-emulation/virt-manager/virt-manager-9999.ebuild
+++ b/app-emulation/virt-manager/virt-manager-9999.ebuild
@@ -1,16 +1,16 @@
 # Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=6
+EAPI=7
 
 PYTHON_COMPAT=( python3_{8,9,10} )
 DISTUTILS_SINGLE_IMPL=1
 
 DISTUTILS_USE_SETUPTOOLS=no
-inherit gnome2 distutils-r1
+inherit gnome2 distutils-r1 optfeature
 
 DESCRIPTION="A graphical tool for administering virtual machines"
-HOMEPAGE="http://virt-manager.org"
+HOMEPAGE="https://virt-manager.org https://github.com/virt-manager/virt-manager"
 
 if [[ ${PV} = *9999* ]]; then
 	inherit git-r3
@@ -19,7 +19,7 @@ if [[ ${PV} = *9999* ]]; then
 	EGIT_BRANCH="master"
 else
 	SRC_URI="http://virt-manager.org/download/sources/${PN}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~ppc64 ~x86"
+	KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
 fi
 
 LICENSE="GPL-2"
@@ -42,17 +42,14 @@ RDEPEND="${PYTHON_DEPS}
 		gnome-base/dconf
 		>=net-libs/gtk-vnc-0.3.8[gtk3(+),introspection]
 		net-misc/spice-gtk[usbredir,gtk3,introspection,sasl?]
-		net-misc/x11-ssh-askpass
 		x11-libs/gtk+:3[introspection]
 		x11-libs/gtksourceview:4[introspection]
 		x11-libs/vte:2.91[introspection]
 		policykit? ( sys-auth/polkit[introspection] )
-	)
-"
-DEPEND="${RDEPEND}
-	dev-python/docutils
-	dev-util/intltool
-"
+	)"
+DEPEND="${RDEPEND}"
+BDEPEND="dev-python/docutils
+	dev-util/intltool"
 
 distutils_enable_tests pytest
 
@@ -63,8 +60,7 @@ src_prepare() {
 }
 
 python_configure() {
-	esetup.py configure \
-		--default-graphics=spice
+	esetup.py configure --default-graphics=spice
 }
 
 python_install() {
@@ -96,4 +92,5 @@ pkg_preinst() {
 
 pkg_postinst() {
 	use gtk && gnome2_pkg_postinst
+	optfeature "SSH_ASKPASS program implementation" lxqt-base/lxqt-openssh-askpass net-misc/ssh-askpass-fullscreen net-misc/x11-ssh-askpass
 }